Aktiva användare på din site
Förord
Det finns flera olika sätt att hålla reda på vilka besökare som för tillfället är aktiva på en sida, tyvärr finns det både för och nackdelar med alla metoder jag känner till. Olika metoder passa olika bra på olika typer av siter, denna metoden är inte på något sätt den bästa, framförallt är den ganska krävande för servern och passar inte så bra på siter med många sid-förfrågningar. Jag har valt att använda mig av en databas för att lagra tidpunkten då varje besökare senast hämtade en sida på webbplatsen, denna tidpunkt jämförs sedan med aktuell tid för att avgöra om besökaren är online eller inte. Fördelen med att använda en databas jämfört med ett applikationsobjekt är att man hela tiden kan presentera information om när en besökare senast accessade en sida (och inte enbart inloggningstidpunkten), nackdelen är förstås att det tar mycket kraft från servern att göra alla uppdateringar och sökningar. Anledningen till att jag valde att uppdatera databasen på varje sida istället för att enbart göra detta vid Session_OnStart och Session_OnEnd är att det vad jag har hört i forumet är problem med att få Session_OnEnd att trigga för alla besökare.
Databasen
För att utnyttja fördelarna med databasen bör du lagra klockslaget i samma databas/tabell som din vanliga användardatabas. För att visa har jag skapat en tabell med följande innehåll i Access. | tblUsers | |
|---|---|
| ID | Räknare |
| strName | Text |
| dteLastAccess | Datum/tid |
ID är ett unikt heltal som fungerar som användar-ID, använder du något annat unikt för varje användare går det också bra.
strName är namnet som visas.
dteLastAccess är tidpunkten då användaren senast besökte webplatsen, det är alltså inte när inloggningen skedde utan när besökaren senast var aktiv.
Uppdatera tiden i databasen
För varje sida som besökaren hämtar måste tidpunkten i databasen uppdateras, detta kan göras på följande sätt:
If Len(Session("ID")) > 0 Then 'om inloggad
Dim ConUpdate
Set ConUpdate = Server.CreateObject("ADODB.Connection")
ConUpdate.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("online.mdb") & _
";Persist Security Info=False"
ConUpdate.Execute "UPDATE tblUsers SET dteLastAccess = Now() WHERE ID = " & Session("ID")
ConUpdate.Close
Set ConUpdate = Nothing
End If
För att slippa skriva denna koden på varje sida kan det vara lämpligt att lägga detta i en egen fil som inkluderas på varje sida.
Visa besökare som är online
För att lista alla som är online för tillfället söker man ut alla som har varit aktiva senare än en viss tidpunkt, i detta fallet 5 minuter innan aktuell tid.
Dim ConOnline, RS
Set ConOnline = Server.CreateObject("ADODB.Connection")
ConOnline.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("online.mdb") & ";Persist Security Info=False"
Set RS = ConOnline.Execute("SELECT strName FROM tblUsers WHERE dteLastAccess > #" & DateAdd("n", -5, Now) & "# ORDER BY strName")
Do Until RS.EOF
Response.Write RS("strName") & "
"
RS.MoveNext
Loop
RS.Close
Set RS = Nothing
ConOnline.Close
Set ConOnline = Nothing
Kontrollera status för en viss användare
För att kontrollera om en specifik anändare är aktiv just nu kan vi jämföra dennes tidstämpel med aktuell tid. Om man gör en funktion av detta kan den inkluderas på alla sidor där man vill kontrollera detta. Detta exempel kontrollerar om besökaren har varit aktiv de senaste 5 minutrarna.
Function IsOnline(ID)
Dim ConIsOnline, RS
Set ConIsOnline = Server.CreateObject("ADODB.Connection")
ConIsOnline.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("online.mdb") & ";Persist Security Info=False"
Set RS = ConIsOnline.Execute("SELECT dteLastAccess FROM tblUsers WHERE ID = " & ID)
If DateDiff("n", RS(0), Now) <= 5 Then
IsOnline = True
Else
IsOnline = False
End If
RS.Close
Set RS = Nothing
ConIsOnline.Close
Set ConIsOnline = Nothing
End Function
0 Kommentarer