Har byggt ihop en liten community och allt fungerar bra tills jag försöker fixa så att varje medlem ska få en egen gästbok blir allt fel.. Kan även hjälpa mig, men var hittatar jag "Stäng av vänliga felmeddelanden..." Hittade det! <code> Hur ser din länk ut? Hur ser resultatet från din sida ut(view source/visa källa)?Hjälp! Sidan kan inte visas... Varför?
Har länkat allt rätt ( tror jag iaf eftersom den delar ut ett id ( las_gb.asp?gbID=<%=Session("UserID")%> ) )
Försöker jag klicka på den länken så står det bara Sidan kan inte visas.. Inga fel medelanden eller ngt ... Vad ska jag göra ?
Kan skicka upp koden för las_gb.asp.
---------------------------------
<%
Dim objConn 'as object
Dim strConn 'as string
Dim strSQL 'as string
Dim lngUserID 'as long
Dim rstGuestbook 'as recordset
Dim strHTML 'as string
Dim strTemp 'a string
lngUserID = Request.QueryString("userID")
if not IsNumeric(lngUserID) then Response.Redirect("inloggad.asp")
Set objConn = server.CreateObject("ADODB.Connection")
strConn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("db/community.mdb")
objConn.Open strConn
strSQL = ""
strSQL = strSQL & "SELECT "
strSQL = strSQL & "tblUsers.userLoginName, "
strSQL = strSQL & "tblGuestbook.gbDateTime, "
strSQL = strSQL & "tblGuestbook.gbText, "
strSQL = strSQL & "tblUsers.userID, "
strSQL = strSQL & "tblGuestbook.gbFromUserID "
strSQL = strSQL & "FROM tblGuestbook "
strSQL = strSQL & "INNER JOIN tblUsers ON tblGuestbook.gbFromUserID = tblUsers.userID "
strSQL = strSQL & "WHERE tblGuestbook.gbUserID = " & lngUserID & " "
strSQL = strSQL & "ORDER BY tblGuestbook.gbDateTime DESC"
Set rstGuestbook = Server.CreateObject("ADODB.Recordset")
rstGuestbook.Open strSQL, objConn, 3, 3
if (rstGuestbook.EOF or rstGuestbook.BOF) then 'Gästboken är tom
strHTML = ""
strHTML = "Tom gästbok."
else 'Gästboken är inte tom
'Skapa html-kod som skall skrivas ut på sidan
strHTML = ""
strHTML = strHTML & "<table border=""0"">"
do while not rstGuestbook.EOF
strHTML = strHTML & "<tr>"
strHTML = strHTML & "<td>"
strHTML = strHTML & "" & rstGuestbook(0) & ""
strHTML = strHTML & " <i>" & left(rstGuestbook(1), len((rstGuestbook(1))-3)) & "</i>" 'Ta bort sekunderna i datum/tiden
strHTML = strHTML & "</td>"
strHTML = strHTML & "</tr>"
strHTML = strHTML & "<tr>"
strHTML = strHTML & "<td>"
'Ta bort ogiltiga tecken i inläggen
strTemp = Replace(rstGuestbook(2), "<", "<")
strTemp = Replace(strTemp, ">", ">")
strHTML = strHTML & strTemp
strHTML = strHTML & "</td>"
strHTML = strHTML & "</tr>"
strHTML = strHTML & "<tr>"
strHTML = strHTML & "<td>"
strHTML = strHTML & "<hr>"
strHTML = strHTML & "</td>"
strHTML = strHTML & "</tr>"
rstGuestbook.MoveNext
loop
strHTML = strHTML & "</table>"
end if
rstGuestbook.Close
Set rstGuestbook = nothing
objConn.Close
Set objConn = nothing
%>
<html>
<head>
<title>Läs gästbok</title>
</head>
<body>
Tillbaka till startsidan<br>
Skriv i gästboken
<br>
<br>
<%
Response.Write(strHTML)
%>
</body>
</html>
/ TACKSAM FÖR ALLA SVAR!Sv: Hjälp! Sidan kan inte visas... Varför?
Stäng av visa vänliga felmeddelanden i Explorer så ser du felet, klart lättare att hjälpa till om man vet vad som felar.Sv: Hjälp! Sidan kan inte visas... Varför?
Sv: Hjälp! Sidan kan inte visas... Varför?
Microsoft JET Database Engine error '80040e14'
Syntax error (missing operator) in query expression 'tblGuestbook.gbUserID ='.
/mupp/las_gb.asp, line 35
--------------------------------------------------------------
RAD: 35. ( las_gb.asp )
strSQL = ""
strSQL = strSQL & "SELECT "
strSQL = strSQL & "tblUsers.userLoginName, "
strSQL = strSQL & "tblGuestbook.gbDateTime, "
strSQL = strSQL & "tblGuestbook.gbText, "
strSQL = strSQL & "tblUsers.userID, "
strSQL = strSQL & "tblGuestbook.gbFromUserID "
strSQL = strSQL & "FROM tblGuestbook "
strSQL = strSQL & "INNER JOIN tblUsers ON tblGuestbook.gbFromUserID = tblUsers.userID "
strSQL = strSQL & "WHERE tblGuestbook.gbUserID = " & lngUserID & " "
strSQL = strSQL & "ORDER BY tblGuestbook.gbDateTime DESC"
Set rstGuestbook = Server.CreateObject("ADODB.Recordset")
rstGuestbook.Open strSQL, objConn, 3, 3
//TACKSAM FÖR ALLA SVAR!Sv: Hjälp! Sidan kan inte visas... Varför?
<%
Dim objConn 'as object
Dim strConn 'as string
Dim strSQL 'as string
Dim lngUserID 'as long
Dim rstGuestbook 'as recordset
Dim strHTML 'as string
Dim strTemp 'a string
Dim fldLoginName
Dim fldDateTime
Dim fldText
Dim fldUserID
Dim fldFromUserID
lngUserID = "" & Request.QueryString("userID")
If IsNumeric(lngUserID) Then
strConn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("db/community.mdb")
Set objConn = server.CreateObject("ADODB.Connection")
objConn.Open strConn
strSQL = "SELECT tblUsers.userLoginName, tblGuestbook.gbDateTime, tblGuestbook.gbText, tblUsers.userID, tblGuestbook.gbFromUserID" & vbCrLf & _
"FROM tblGuestbook LEFT JOIN tblUsers ON tblGuestbook.gbFromUserID = tblUsers.userID" & vbCrLf & _
"WHERE tblGuestbook.gbUserID = " & lngUserID & vbCrLf & _
"ORDER BY tblGuestbook.gbDateTime DESC"
Set rstGuestbook = Server.CreateObject("ADODB.Recordset")
rstGuestbook.Open strSQL, objConn
%>
<html>
<head>
<title>Läs gästbok</title>
</head>
<body>
Tillbaka till startsidan<br>
Skriv i gästboken
<br>
<br>
<%
If rstGuestbook.EOF Then 'Gästboken är tom
Response.Write "Tom gästbok."
Else 'Gästboken är inte tom
Set fldLoginName = rstGuestbook("userLoginName")
Set fldDateTime = rstGuestbook("gbDateTime")
Set fldText = rstGuestbook("gbText")
Set fldUserID = rstGuestbook("userID")
Set fldFromUserID = rstGuestbook("gbFromUserID")
'Skapa html-kod som skall skrivas ut på sidan
Response.Write "<table border=""0"">"
Do Until rstGuestbook.EOF
Response.Write "<tr><td>"
Response.Write "" & fldLoginName.Value & ""
'Ta bort sekunderna i datum/tiden
Response.Write " <i>" & FormatDateTime(fldDateTime.Value, vbShortDate) & " " & FormatDateTime(fldDateTime.Value, vbShortTime) & "</i>"
Response.Write "</td></tr>"
Response.Write "<tr><td>" & Server.HTMLEncode(fldText.Value) & "</td></tr>"
Response.Write "<tr><td><hr></td></tr>"
rstGuestbook.MoveNext
Loop
Response.Write "</table>"
Set fldLoginName = Nothing
Set fldDateTime = Nothing
Set fldText = Nothing
Set fldUserID = Nothing
Set fldFromUserID = Nothing
End If
Response.Write "</body>"
Response.Write "</html>"
rstGuestbook.Close
Set rstGuestbook = nothing
objConn.Close
Set objConn = nothing
Else
Response.Redirect("inloggad.asp")
End If
%>
</code>Sv: Hjälp! Sidan kan inte visas... Varför?