Med följande kod skapar ja en fil

<code>
Dim fso, filename

filename= "bGasp.asp"

set fso = CreateObject("Scripting.FileSystemObject")
Set MyFile = FSO.CreateTextFile(Server.mappath("Filer/" & filename))

</code>

Filen hamnar i mappen filer.

Nu vill jag kunna läsa filen och få ut

namn
Storlek
Skapad


Jag har mekat och vridit på 'getfile' metoden

men jag får det f--n tomme inte att fungera... Jag får meddelanden som säger
" Objekt kräv....." " Hittar inte filen...."


Alltså! Jag vill läsa av namnet, storleken, skapaddatum på den fil som finns i mappen filer.

Lite hjälp på vägen vore trevligt

/phinala

Sök på "FSO" i såväl tips & tricks som artiklar för att se hur du gör. För att kunna svara på hur du får ut din information sen så måste man få se hur filens innehåll ser ut.

Dett borde fungera.
Ett tips. Skaffa VB Script Documentation (finns på MS-site)

<code><%
Dim strFilepath ' As String
Dim objFSO ' As Object
Dim objFile ' As Object

strFilepath = Server.MapPath("/fso/filen.txt")

Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
'## -- vi skapar en ny fil och öppnar den --
Set objFile = objFSO.CreateTextFile(strFilepath, true)
'## -- stänger den nyss skapade filen --
objFile.Close

'## -- frigör lite object --
Set objFile = Nothing

'## -- hämta filinformation --
Set objFile = objFSO.GetFile(strFilepath)
'## -- skriv ut diverse information om filen --
Response.Write ("Name: " & objFile.Name & "<br>Path: " & objFile.Path & _
"<br>Size: " & objFile.Size & "<br>Created: " & objFile.DateCreated)

'## -- frigör objekten --
Set objFile = Nothing
Set objFSO = Nothing
%>
</code>

cya,
/PatrikB

Hej!


Jag skall prova ditt tipps... Jga har gått igenom alla tips och tricks ... mn inte kommit någon vart...

/Tyronne

Super bra! Mr


Nu fungerar det..

Bugar och tackar

/phinala