Har googlat lite samt sökt här i forumet men inte hittat något svar som hjälpt :-(

Jag använder CDONTS för att skicka et mail från en ASP-sida. Det fungerar finfint så länge jag skickar innehållet som html ELLER plain-text. Men jag vill att om mottagaren (mailklienten) inte kan/vill läsa html-mail så ska en textversion visas.

Jag har fattat att det är multipart som ska användas men jag får inte till det!
Någon som har bra kod där jag enkelt kan lägga in min text eller html-innehåll?

Du kan aldrig få reda på om klienten kan läsa eller inte. Betänk att han kan använda ett program eller en webbklient för läsningen och därför är det omöjligt att känna av detta enligt mina kunskaper i alla fall.

Du får nog göra så att du helt enkelt får fråga mottagaren om denne kan läsa eller inte.

Dock kan man idag i de flesta fall skicka via html, och den mesta texten är i alla fall läsbar trots vissa skavanker. Se dock till att på image-taggarna lägga till en alt-tagg och beskriv vad bilden skall föreställa så går det att förstå innebörden.

Hittar du nåt eller kommer på något briljant - dela gärna med dig av dina upptäkter.

Hmmm... när jag surfat runt och letat så verkar det som om det ska gå. Jag behöver ju inte veta om mottagaren kan/vill visa HTML. Tanken är att skicka båda så får klienten välja.

Har sett lösningar som definierar MIME typ och är i multipart/mixed. De påstår att läsaren (klient eller servern som skapar webmailet) väljer att visa html om den klarar det. Men eftersom jag inte ens lyckas skicka såna mail kan jag inte kolla om det stämmer...
Här http://www.thaifast.com/Microsoft_Books/Sample/607729c06.pdf skriv om detta. Men som sagt jag förstår inte hur jag ska få det att fungera.

Har försökt med tex:
http://msdn.microsoft.com/library/default.asp?url=/library/en-us/cdosys/html/_cdosys_examples_constructing_a_bodypart_hierarchy.asp
Men fattar inte riktigt hur jag ska få det att fungera... suck! Någon som kan tyda det som står där och hur man kan använda det för att skicka mail (sådana som jag önskar ovan) med ASP?

Har sett denna fråga (på p2p.wrox.com):
Is there any way that I can do to send email in an HTML format with CDONTS and allow people whose email app unable to pick up the html format can view the email in the ormal text format?
Med detta svar:
You can't use CDONTS NewMail object to do it. You have to create a CDO
Message object and then construct each body part seperately and add it
using the AddBodyPart method.

Då undrar man ju hur går detta (som beskrivs i svaret) till?

Nu har jag hållt på med detta ett tag och äntligen hittat nått som (jag tror) funkar!
<code><%
myTextBody="Hej detta är ett mail i textformat"
myHTMLBody="<strong>Hej!</strong><br>Detta är ett mail i <em>HTML</em>format."

cdoAnonymous = 0
cdoBasic = 1
cdoSendUsingPickup = 1
cdoSendUsingPort = 2

'mailobjekt
SET mailer = server.CreateObject("CDO.message")
'konfigurationsobjekt som håller inställningarna för att skicka mailet
SET conf = server.CreateObject("CDO.configuration")

mailer.TextBody = myTextBody
mailer.HTMLBody = myHTMLBody
mailer.From = "Ditt Namn"
mailer.Sender = "du@dinepostadress.nu"
mailer.Subject = "Multipartmail!"
mailer.To = "mottagare@enmailserver.net"
'mailer.CC = "kopia@enmailserver.net"
'mailer.BCC = "hemlig@enmailserver.net"

'metoden för att skicka
conf.Fields.item("http://schemas.microsoft.com/cdo/configuration/sendusing") = cdoSendUsingPort
'mailserver. IP eller namn
conf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "din.mailserver.net"
'vilken port lyssnar servern på
conf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
'authenticeringsmetod. välja cdoanonymous om den ej kräver authenticering
conf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic
'username och password om servern kräver authenticering
conf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = "användarnamn"
conf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "lösenord"

mailer.Configuration = conf
mailer.Configuration.fields.update
mailer.Send

SET mailer=nothing
SET conf=nothing
%></code>