Sv: Fel på rad 42!!!!

Fel på rad 42!!!!

Postades av 2004-05-15 18:06:38 - Torbjörn Karlberg, i forum asp - allmänt, Tråden har 13 Kommentarer och lästs av 718 personer

Tjena!
Kan någon som är haj på detta kolla varför jag får fel i denna kod, hämtad från gruvjo.com Chatt v2.
jag har laggt upp databasen på servern och den funkar och chatten startar från sidan top.asp som läser in databasen men det blir fel i sidan mess.asp.

<table width="100%" cellpadding="0" cellspacing="0">

<%Set RS = Conn.Execute("Select * From mess order by id desc")

Do Until RS.EOF%>
<tr>
'fel på denna rad' <td><span style="color: #008000;">[<%=FormatDateTime(RS("datum"),4)%>]</span> <b><%=RS("fran")%><%If RS("fran") <> "" Then%>:<%End If%></b> <%=Kod(RS("Inlagg"))%

></td>
</tr>
<%RS.MoveNext
Loop
RS.Close
Set RS = Nothing%>
</table>

Hoppas någ förstår vad jag menar med detta.

tja
Tobbe

Svara

Sv: Fel på rad 42!!!!

Postades av 2004-05-15 18:29:54 - Anna-Karin Söderberg

Det blir lite lättare att svara om du talar om vad felmeddelandet är, nu får vi gissa och ha oss.

Den som har kodat är dessutom inte bra på det. Jag vet inte om det finns fler fel, men ett stort finns i den du visade.

<code>
<%
Response.write RS("fran")
If RS("fran") <> "" Then
Response.write ":"
End If
Response.write RS("Inlagg")

</code>

Men ska man kunna rätta detta så behöver man se mer av koden.

Sen om det ligger på en server med engelsk operativsystem så kan man behöva sätta LCID till svenskt format. Detta gör du med Session.LCID= 1053

//Anna-Karin

Svara

Sv: Fel på rad 42!!!!

Postades av 2004-05-15 19:21:09 - Torbjörn Karlberg

Tjena! lite info om felet
Error Type:
Sun ONE ASP VBScript compilation (0x800A03F2)
Expected identifier
/chatt2@45/mess.asp, line 43, column 1

De här är koden för sidan mess.asp




<%dDate = DateAdd("n",-10,Now())

Conn.Execute("Delete From chat Where datum < #" & dDate & "#")

dDate = DateAdd("n",-10,Now())
Conn.Execute("Delete From mess Where datum < #" & dDate & "#")

dDate = DateAdd("h",-1,Now())
Conn.Execute("Delete From online Where date < #" & dDate & "#")

If Request.QueryString("do") = "add" Then
Set RS = Conn.Execute("Select * From online Where namn='" & Session("UserName") & "'")
If Not RS.EOF Then
Inlagg = Tecken(Request.Form("mess"))
Fran = Request.Form("fran")
Ip = Request.Servervariables("REMOTE_ADDR")

If Inlagg <> "" Then
Conn.Execute("Insert Into mess(inlagg,fran,ip) Values('" & Inlagg & "','" & Fran & "','" & Ip & "')")
Response.Redirect "mess.asp"
Else
Response.Redirect "mess.asp"
End If
Else%>
<script language="JavaScript">
top.location.href="default.asp";
</script>
<%End If
End If%>

<meta http-equiv="refresh" content="5">
<body bgcolor="<%=Messbgfarg%>">

<table width="100%" cellpadding="0" cellspacing="0">

<%Set RS = Conn.Execute("Select * From mess order by id desc")

Do Until RS.EOF%>
<tr>
(Rad43) <td><span style="color: #008000;">[<%=FormatDateTime(RS("datum"),4)%>]</span> <%=RS("fran")%><%If RS("fran") <> "" Then%>:<%End If%> <%=Kod(RS("Inlagg"))%

></td>
</tr>
<%RS.MoveNext
Loop
RS.Close
Set RS = Nothing%>
</table>

</body>
</html>

<%Conn.Close
Set Conn=Nothing%>

Tja!
Tobbe

Svara

Sv: Fel på rad 42!!!!

Postades av 2004-05-15 19:33:50 - Andreas Hillqvist

<code>


<%
Dim dDate
dDate = DateAdd("n",-10,Now())
Conn.Execute "Delete From chat Where datum < #" & dDate & "#"

dDate = DateAdd("n",-10,Now())
Conn.Execute("Delete From mess Where datum < #" & dDate & "#")

dDate = DateAdd("h",-1,Now())
Conn.Execute("Delete From online Where date < #" & dDate & "#")

Set RS = Server.CreateObject("ADODB.Recordset")
Select Case Request.QueryString("do")
Case "add"
RS.Open "Select * From online Where namn='" & Session("UserName") & "'", Conn

If Not RS.EOF Then
Inlagg = Tecken(Request.Form("mess"))
Fran = Request.Form("fran")
Ip = Request.Servervariables("REMOTE_ADDR")

If Len(Inlagg) > 0 Then
Conn.Execute "Insert Into mess(inlagg, fran, ip) Values('" & Inlagg & "', '" & Fran & "', '" & Ip & "')"
End If
End If
Case Else
End Select

<meta http-equiv="refresh" content="5">
<body bgcolor="<%=Messbgfarg%>">
<table width="100%" cellpadding="0" cellspacing="0">
<%
RS.Open "Select * From mess order by id desc", Conn

Do Until RS.EOF
Response.Write "<tr><td><span style=""color: #008000;"">[" & FormatDateTime(RS("datum"), 4) & "]</span>"

If Len(RS("fran")) > 0 Then
Response.Write RS("fran") & ": "
End If

Response.Write Kod(RS("Inlagg"))
Response.Write "</td></tr>"

RS.MoveNext
Loop

RS.Close
Set RS = Nothing

Conn.Close
Set Conn=Nothing

%>
</table>
</body>
</html>
</code>

Svara

Sv: Fel på rad 42!!!!

Postades av 2004-05-15 19:44:37 - Torbjörn Karlberg

Tjena

Får med denna kod felmess.
Error Type:
Sun ONE ASP VBScript compilation (0x800A03F2)
Expected identifier
/chatt2@45/mess.asp, line 31, column 1

<meta http-equiv="refresh" content="5">

Som sagt jag är helt rudis på detta.

Tja!!!
Tobbe

Svara

Sv: Fel på rad 42!!!!

Postades av 2004-05-15 19:53:18 - Andreas Hillqvist

Opps. Missat en tag.

<code>


<meta http-equiv="refresh" content="5">
<body bgcolor="<%=Messbgfarg%>">
<table width="100%" cellpadding="0" cellspacing="0">
<%
Dim dDate
If Now() > Application("TimeOut") Then
dDate = DateAdd("n",-10,Now())
Conn.Execute "Delete From chat Where datum < #" & dDate & "#"

dDate = DateAdd("n",-10,Now())
Conn.Execute "Delete From mess Where datum < #" & dDate & "#"

dDate = DateAdd("h",-1,Now())
Conn.Execute "Delete From online Where date < #" & dDate & "#"

Application.Lock
Application("TimeOut") = DateAdd("n", +1, Now())
Application.Unlock
End If

Set RS = Server.CreateObject("ADODB.Recordset")

Select Case Request.QueryString("do")
Case "add"
RS.Open "Select * From online Where namn='" & Session("UserName") & "'", Conn

If Not RS.EOF Then
Inlagg = Tecken(Request.Form("mess"))
Fran = Session("UserName") 'Request.Form("fran")
Ip = Request.Servervariables("REMOTE_ADDR")

If Len(Inlagg) > 0 Then
Conn.Execute "Insert Into mess(inlagg, fran, ip) Values('" & Inlagg & "', '" & Fran & "', '" & Ip & "')"
End If
End If

RS.Close
End Select

RS.Open "Select * From mess order by id desc", Conn

Do Until RS.EOF
Response.Write "<tr><td><span style=""color: #008000;"">[" & FormatDateTime(RS("datum"), 4) & "]</span>"

If Len(RS("fran")) > 0 Then
Response.Write RS("fran") & ": "
End If

Response.Write Kod(RS("Inlagg"))
Response.Write "</td></tr>"

RS.MoveNext
Loop

RS.Close
Set RS = Nothing

Conn.Close
Set Conn=Nothing

%>
</table>
</body>
</html>
</code>

Svara

Sv: Fel på rad 42!!!!

Postades av 2004-05-15 20:01:11 - Torbjörn Karlberg

Tjena Andreas verkar funka med din senaste kod men då fick jag fel i top.asp.

Error Type:
Sun ONE ASP VBScript runtime (0x800A01F5)
Illegal assignment: 'regExp'
top.asp, line 24

<html>
<head>
<title>Gruvsjo.com´s Webchatt</title>
<script src="js.js"></script>
<link rel="stylesheet" href="stil.css" type="text/css">
</head>



<%Set conn = Server.CreateObject("ADODB.Connection")
Conn.Open "DSN=XXXXX;Password=XXXXXXX"

Function Kod(strText)
strText = Server.HTMLEncode(strText)
Set regExp = New regexp
regExp.Global = true
regExp.IgnoreCase = true
regExp.Pattern = "\[color=(.*?)\]"
strText = regExp.Replace(strText,"<font color=""$1"">")
regExp.Pattern = "(\[\/color\])"
strText = regExp.Replace(strText,"</font>")
regExp.Pattern = "\[(b|/b|i|/i|u|/u)\]"
strText = regExp.Replace(strText,"<$1>")
Kod = strText ' Skriver ut texten, uppdelad och fin!
End Function

Function Tecken(str)
Tecken = Replace(Trim(str),"'","''")
End function%>

Verkar som en väldigt bråkig chatt jag har hittat.

O tack för att ni orkar bry er om detta:-/

Tja!!
Tobbe

Svara

Sv: Fel på rad 42!!!!

Postades av 2004-05-15 20:06:48 - Anna-Karin Söderberg

Kör du "riktig" asp eller "fusk" asp?
Fusk-asp är vad t ex b-one kör, de kör linuxburkar med en asp tolk installerad, den har inte samma stöd för asp som windowsburkar har.

//Anna-Karin

Svara

Sv: Fel på rad 42!!!!

Postades av 2004-05-15 20:11:54 - Torbjörn Karlberg

Tjena!

Jag har minna sidor på www.Space2u.com webhotell och vet inte hur dom har det????

Detta står att läsa hos dom.

Vår standadkonfiguration för webbservrarna är Linux med Apache webbserver. Vi har även Windows maskiner med IIS server för de som hellre vill ha kontot på en sådan maskin, IIS servern är tillgänglig från steg 2. JSP, servlets, Telnet/SSH och CGI är inte tillgängligt på IIS servern.

Tja!
Tobbe(:-\)=

Svara

Sv: Fel på rad 42!!!!

Postades av 2004-05-15 20:17:14 - Andreas Hillqvist

Du kör SUN's ASP tolk vilket tyvär inte stödjer allt.

Testa att ersätta:
<code>
Set regExp = New regexp
</code>
Med:
<code>
Set regExp = CreateObject("VBScript.RegExp")
</code>

Svara

Sv: Fel på rad 42!!!!

Postades av 2004-05-15 20:34:47 - Torbjörn Karlberg

Tjena
Nix funkar inte med Set regExp = CreateObject("VBScript.RegExp")

Kan man kringå detta på något sätt eller.

Svara

Sv: Fel på rad 42!!!!

Postades av 2004-05-15 22:02:20 - Andreas Hillqvist

Jepp. Istället för att använda regexp kan du använda Instr() funktionen.

Svara

Sv: Fel på rad 42!!!!

Postades av 2004-05-16 21:44:27 - Patrik Wårdmark

Eftersom din ISP skriver "Vi har även Windows maskiner med IIS server för de som hellre vill ha kontot på en sådan maskin" kanske du borde be att få ha kontot på en Windows maskin istället, om ASP är språket du satsat på.

Svara

Sv: Fel på rad 42!!!!

Postades av 2004-05-17 08:33:24 - Torbjörn Karlberg

Tack för all hjälp med detta skall kanske låta dom byte server.

Känner nu att jag har mer nytta av ASP än jsp,cgi och dom andra sakerna som jag losar med detta.

Tobbe

Svara

Fel på rad 42!!!!

Sv: Fel på rad 42!!!!

Sv: Fel på rad 42!!!!

Sv: Fel på rad 42!!!!

Sv: Fel på rad 42!!!!

Sv: Fel på rad 42!!!!

Sv: Fel på rad 42!!!!

Sv: Fel på rad 42!!!!

Sv: Fel på rad 42!!!!

Sv: Fel på rad 42!!!!

Sv: Fel på rad 42!!!!

Sv: Fel på rad 42!!!!

Sv: Fel på rad 42!!!!

Sv: Fel på rad 42!!!!

Nyligen

Sidor

Statistik

Kontakta oss