Det var ett tag sedan jag jobbade med XML och jag har helt glömt hur man gör..

Jag vill helt enkelt hämta infon från http://www.ecb.int/stats/eurofxref/eurofxref-daily.xml och antingen lagra i en hög med application variables eller i en databas.. vilket som - jag vill kunna gå igenom den valuta för valuta samt hämta ut datumet från filen (<Cube time="2005-08-03">)

Jag har redan surfat webben runt i jakt på exempel men av någon sjuk anledning så begriper jag mig inte på dom alls just nu

Here u go..

<code>
<script language="VBScript" runat="server">
function DisplayXML()
Dim xmlDOC
Dim bOK
Dim HTTP
Set HTTP = CreateObject("MSXML2.XMLHTTP")
Set xmlDOC =CreateObject("MSXML.DOMDocument")
xmlDOC.Async=False
HTTP.Open "GET","http://www.ecb.int/stats/eurofxref/eurofxref-daily.xml", False
HTTP.Send()
bOK = xmlDOC.load(HTTP.responseXML)

if Not bOK then
Response.Write("Error loading XML")
else
Dim objNodeList
DIm objDate
Set objNodeList=xmlDOC.documentElement.selectNodes("Cube/Cube/Cube")
Set objDate=xmlDOC.documentElement.selectSingleNode("Cube/Cube")
Response.Write("Datum: ")
Response.Write(objDate.attributes(0).value & "<p>")

For I = 0 to objNodeList.Length -1
Response.Write(objNodeList(i).attributes(0).value)
Response.Write(": ")
Response.Write(objNodeList(i).attributes(1).value)
Response.Write("<br>")
next
end if


end Function

DisplayXML
</script>
</code>

Underbart! tack så mycket funkar perfekt

Bör man inte använda namnen på attributerna? Annars försvinner väl en del av tjusningen med XML. Att man kan lägga till information och/eller ändra ordning på attributer utan att påverka kompaibilitet.

<%
Dim xmlDOC 'As MSXML2.DOMDocument
Dim bOK
Dim HTTP 'As MSXML2.XMLHTTP

    Set HTTP = CreateObject("MSXML2.XMLHTTP")
    Set xmlDOC = CreateObject("MSXML2.DOMDocument")
    
    xmlDOC.Async = False
    HTTP.Open "GET", "http://www.ecb.int/stats/eurofxref/eurofxref-daily.xml", False
    HTTP.Send
    bOK = xmlDOC.Load(HTTP.responseStream)

    If Not bOK Then
        Response.Write "Error loading XML"
    Else
        Dim objNode 'As MSXML2.IXMLDOMNode
        Dim objNodeList 'As MSXML2.IXMLDOMNodeList
        Dim objAttributes 'As MSXML2.IXMLDOMNamedNodeMap
        
        Set objNode = xmlDOC.documentElement.selectSingleNode("Cube/Cube")
        Set objNodeList = xmlDOC.documentElement.selectNodes("Cube/Cube/Cube")
        
        Response.Write "Datum: "
        Response.Write objNode.Attributes.getNamedItem("time").nodeValue & "<p>" & vbCrLf
        
        For Each objNode In objNodeList
            Set objAttributes = objNode.Attributes
            Response.Write objAttributes.getNamedItem("currency").nodeValue
        
            Response.Write ": "
            Response.Write objAttributes.getNamedItem("rate").nodeValue
            Response.Write "<br>" & vbCrLf
        Next
    End If
%>