Hej
Jag vill loopa ut 5 bilder i rad och text under varje bild.
Jag får inte till det så jag skulle bli glad om jag får lite hjälp
Så här ser koden ut:
set RS = Server.CreateObject("ADODB.Recordset")
sSQL = "select navbild, text from nav"
RS.open sSQL, sDSN
If Not RS.Eof then
Do until RS.EOF%>
<%response.write RS("navbild") & vbcrlf & vbcrlf%>
<%response.write RS("text") & vbcrlf%>
<%RS.MoveNext
Loop
End if
%>

Använd dig av DIV eller TABLE för att det skall bli korrekt.
Skriv ut <BR> efter bild så kommer texten under bilden.

Skall bilderna komma jämte varandra eller under?

Ja bilderna ska komma jämte varandra och det är det som jag inte får till
Skriv gärna i min kod hur det ska se ut

Skall du bara ha 5 bilder eller 5 bilder per rad?

Här visas endast en rad med fem bilder:

<%
sSQL = "select TOP 5 navbild, text from nav"
RS.open sSQL, sDSN
If Not RS.Eof then%>
	<TABLE CELLPADDING=2 CELLSPACING=4 BORDER=0><TR><%Do until RS.EOF%>
      <TD align="center" valign="top"><%response.write RS("navbild") &  "<BR>"%>
      <%response.write RS("text") &  vbcrlf%></TD>
      <%RS.MoveNext
Loop%>
 </TR></TABLE>
<%End if 


'*** Eller om du vill köra flera rader med fem bilder per rad
SQL="select navbild, text from nav"
RS.OPEN SQL, sDSN 
antalbilderperrad=5
if not RS.EOF then
	galleryData = RS.GetRows()
	RS.CLOSE
	imagesfromsameevent=0
	response.write "<TABLE CELLPADDING=2 CELLSPACING=4 BORDER=0><TR>"&VbCrLf
	for i=0 to UBOUND(galleryData,2)				
		imagesfromsameevent=imagesfromsameevent+1
		if imagesfromsameevent > antalbilderperrad then 
			response.write "</TR><TR>"&VbCrLf
			imagesfromsameevent = 1
		end if
		response.write "<TD align=""center"" valign=""top"">"&_
"<IMG SRC=""images/gallery/thumbs/"&galleryData(0,i)&""" border=0><BR>"&_
galleryData(1,i)&"</TD>"&VbCrLf	
		bilderutskrivna = bilderutskrivna +1
	next
	response.write "</TR></TABLE>"&VbCrLf
else
	RS.close
	'Response.write "<I>Hittade inga bilder</I><BR><BR>"
end if
%>