Jag håller på med att fixa en nyhet som föst skriver ut en nyhet.
Sen så ska den skriva ut alla andra nyheter med en HR tagg åvanför sig.

Måste jag använda mig av 2 SQL:er?
En som skriver ut det fösta inlägget och sedan resten med HR tagg eller
går detta att göra med en enda SQL kod?

EX.
<code>
id: 1 Rubrik - Datum
Meddelande
<hr>
id: 2 Rubrik - Datum
Meddelande
<hr>
id: 3 Rubrik - Datum
Meddelande
<hr>
id: 4 Rubrik - Datum
Meddelande
</code>

Alltså det ska inte vara någon HR åvanför första inlägget och ingen efter sista.

Löste det på detta sätt:

<%
	call connOpen()

	Dim fID, SQL, RecSet
	SQL = "SELECT * FROM aq_news WHERE strDeleted=0 ORDER BY id DESC LIMIT 1"
	Set RecSet = Conn.Execute(SQL)
	Do until RecSet.EOF

		fID = RecSet("id")
		Response.Write "<SPAN style=""COLOR: #ffffff;"">" & vbcrlf
		Response.Write "<B>"& RecSet("strHeadline") &" - "& ConvertToSwedishLongDate(RecSet("strDate")) &"</B>" & vbcrlf
		Response.Write "</SPAN><BR>" & vbcrlf
		Response.Write RecSet("strMessage") & vbcrlf
	
	Recset.MoveNext
	Loop
	Recset.Close
	Set RecSet = Nothing
	
	'###################################################################
	
	SQL = "SELECT * FROM aq_news WHERE strDeleted=0 AND id<"& fID &"  ORDER BY id DESC"
	Set RecSet = Conn.Execute(SQL)
	Do until RecSet.EOF

		Response.Write "<HR>" & vbcrlf
		Response.Write "<SPAN style=""COLOR: #ffffff;"">" & vbcrlf
		Response.Write "<B>"& RecSet("strHeadline") &" - "& ConvertToSwedishLongDate(RecSet("strDate")) &"</B>" & vbcrlf
		Response.Write "</SPAN><BR>" & vbcrlf
		Response.Write RecSet("strMessage") & vbcrlf
	
	Recset.MoveNext
	Loop
	Recset.Close
	call connClose()
%>

Du kan använda dig av getrows?!

<%Dim fID, SQL, RecSet
    SQL = "SELECT Id, strHeadline, strDate, strMessage FROM aq_news WHERE strDeleted=0 ORDER BY id DESC"
    Set RecSet = Conn.Execute(SQL)
Arraydata=RecSet.Getrows()
RecSet.Close
Set RecSet = Nothing
    
For i=0 to Ubound(ArrayData,2)
        fID = ArrayData(0,i)
If i> 0 Then Response.Write "<HR>" & vbcrlf
        Response.Write "<SPAN style=""COLOR: #ffffff;"">" & vbcrlf
        Response.Write "<b>"& ArrayData(1,i) &" - "& ConvertToSwedishLongDate(ArrayData(2,i)) &"</b>" & vbcrlf
        Response.Write "</SPAN><BR>" & vbcrlf
        Response.Write ArrayData(3,i) & vbcrlf
    
    Next%>
    

Tack så mycket ;)