Hej!

Jag vill göra en funktion som infogar valfri textsträng i början av varje rad i en textfil.

Jag har gjort ett exempel som SKRIVER UT textfilen så som jag tänkt mig att den ska SPARAS (där jag valt att "1," ska skrivas i början av varje rad). Har inte riktigt koll på hur jag ska göra för att den ska skriva till textfilen så som jag vill :)

<%

   Set txt = Server.CreateObject ("Scripting.FileSystemObject")
   Set Lasa = txt.OpenTextFile (Server.MapPath("test.txt"))
   
   Do While not Lasa.AtEndofstream
      Response.write "1," & Lasa.Readline & "<BR>"
   Loop
   
   Set Lasa=Nothing

%>

Hej Oskar

<b>Anrop:</b>

<%
AppendFile "1,", Server.MapPath("test.txt")
%>

<%
Sub AppendFile(prefix, fileAddress)
 Dim rows(), counter, i
 Dim fso, input, output

 ' File System Object.
 Set fso = Server.CreateObject("Scripting.FileSystemObject")

 ' Initialization.
 counter = 0
 ReDim rows(0)

 ' File to array.
 Set input = fso.OpenTextFile(fileAddress)
 Do While Not input.AtEndofstream
  If counter Mod 10 = 0 Then ReDim Preserve rows(UBound(rows) + 10)          
  rows(counter) = input.ReadLine
  counter = counter + 1
 Loop
 input.Close
 Set input = Nothing 

 ' Redimension array
 ReDim Preserve rows(counter-1)

 ' "Edit" file.
 Set output = fso.CreateTextFile(fileAddress)
 For i=0 To counter-1
  output.WriteLine prefix & rows(i)
 Next
 output.Close
 Set output = Nothing
End Sub
%>

Tusen tack för hjälpen Peter!

Jag har gjort lite redigeringar så jag kan få det som jag vill ha det i slutändan. Försöker göra så man själv kan välja textfil.

Får detta felmeddelandet
Feltyp:
Server.MapPath(), ASP 0172 (0x80004005)
Parametern Path för metoden MapPath måste vara en virtuell sökväg. En fysisk sökväg har använts.

Jag förstår felet, men inte hur man åtgärdar det! Scriptet ska funka oavsett vilken dator man använder!

<form name="do" method="post" action="?do=CreateThatCoolTextFile">
Välj textfil: <input name="textfile" type="file" /><br />
Välj textsträng: <input name="textStr" type="text" /><br />
<input type="submit" value="HIT IT!" />
</form>

<%
If Request.Querystring("do") = "CreateThatCoolTextFile" Then

	Dim textfile, textStr
	textfile = Request.Form("textfile")
	textStr = Request.Form("textStr")

	AppendFile ""&textStr&"", Server.MapPath(""&textfile&"")
		
	Sub AppendFile(prefix, fileAddress)
	 Dim rows(), counter, i
	 Dim fso, input, output
	
	 ' File System Object.
	 Set fso = Server.CreateObject("Scripting.FileSystemObject")
	
	 ' Initialization.
	 counter = 0
	 ReDim rows(0)
	
	 ' File to array.
	 Set input = fso.OpenTextFile(fileAddress)
	 Do While Not input.AtEndofstream
	  If counter Mod 10 = 0 Then ReDim Preserve rows(UBound(rows) + 10)          
	  rows(counter) = input.ReadLine
	  counter = counter + 1
	 Loop
	 input.Close
	 Set input = Nothing 
	
	 ' Redimension array
	 ReDim Preserve rows(counter-1)
	
	 ' "Edit" file.
	 Set output = fso.CreateTextFile(fileAddress)
	 For i=0 To counter-1
	  output.WriteLine prefix & rows(i)
	 Next
	 output.Close
	 Set output = Nothing
	End Sub

End If
%>

Ändra

AppendFile ""&textStr&"", Server.MapPath(""&textfile&"")

AppendFile textStr, textfile

Fungerar perfekt :) Tack så hemskt mycket för hjälpen!

borde inte.. detta funka lika bra

myText = replace(myText, vbcrlf, vbcrlf & stringToAdd)