Jag har en databaskopplad ASP-webbapplikation som fungerar utmärkt idag. Mitt problem är att jag vill börja utnyttja global.asa-filen men får inte anslutningen till databasen att fungera då. Sorry för ”låg nivå” men jag hittar verkligen inte lösningen själv.

Idag ansluter jag till min accessdatabas så här:

Dim adoCon
Dim rsCOB
Dim strSortField
Set adoCon = Server.CreateObject("ADODB.Connection")
adoCon.Open "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("../fpdb/Data.mdb")
Set rsCOB = Server.CreateObject("ADODB.Recordset")
strSortField = Request.QueryString("field")
…
Absolut sökväg till databasen är: c:\webbtest\fpdb\Data.mdb

Tre frågor:
1. Hur använda global.asa? Tänkte utnyttja ”Sub Application_OnStart”
2. Vad skriver jag in i min webbapplikation i stället?
3. Jag förmodar att enbart delar av raden ”adoCon.Open "DRIVER=…” är vad som skall in i global.asa men att själva databaskopplingen skall göras i webbapplikationen precis som idag?

Har letat febrilt på nätet men hittar tyvärr inga svar som fungerar för mig, och mitt eget expremeterande leder tyvärr inte heller frammåt...

global.asa

<script language="vbscript" runat="server">

sub Application_OnStart
    Application.Lock
    Application("ConnectionString") = _
        "Provider=Microsoft.Jet.OLEDB.4.0;" + _
        "Data Source=" + Server.MapPath("../fpdb/Data.mdb")
    Application.UnLock
end sub

sub Application_OnEnd
  'some code
end sub

sub Session_OnStart
  'some code
end sub

sub Session_OnEnd
  'some code
end sub

</script>

Dim con
Dim rsCOB
Dim strSortField
     Set con = Server.CreateObject("ADODB.Connection")
     con.Open Application("ConnectionString")

     Set rsCOB = Server.CreateObject("ADODB.Recordset")
     rsCOB.Open "SELECT * FROM TableName", con

     '...

     rsCOB.Close

     con.Close

Tack!

Det var ju inte så svårt... Har precis testat och det fungerar - stort tack för hjälpen :-)

Det var så lite så.