Hej!
Jag får inte följande kod att fungera, Finns det ingen bild så skall en viss bild visas istället för en vanlig tom bild. Men finns bilden i mappen så skall den visas istället. Vad är fel? får inga felmeddelanden och bara den alternativa bilden visas. Dom riktiga bilderna finns i mappen.
<code>
Dim Connect, Rst, filnamn, fso

Set Connect = Server.CreateObject("ADODB.Connection")
Connect.Open "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=" & Server.MapPath("db/db.mdb")

sql = "select top 5 * from objects order by objectid desc"
Set Rst = connect.Execute(sql)
Do while not Rst.EOF
'Sökvägen till min fil.
Filnamn = "http://www.min url/images/Rst(""bild"")"
'skapar "FileSystemObject"
Set fso = server.CreateObject("Scripting.FileSystemObject")
If (fso.FileExists(Filnamn)) then%>
<IMG width="50" height="75" SRC="images/<%=Rst("bild")%>"alt="<%=Rst("Title")%>"
<%else%>
<IMG width="50" height="75" SRC="images/npa.gif" ></a>
<%end if

'stänger objectet
set fso = nothing
Rst.MoveNext
loop
%>
</code>
Tack på förhand för alla svar
//Jocke

FSO är en server sida komponent och där måste man ange fysiska sökvägar på servern
t ex d:\inetpub\wwwroot\mappen\bilder\bilden.jpg

om du inte kan mappstrukturen kan du lägga in en fil som heter "test.asp" i din bildmapp med följande kod:
<code:asp>
<%
response.write server.mappath("./")
%>
</code>
Då får du sökvägen till mappen.

Tack för tippset med din kod till att hitta rätt sökväg, men tyvärr så hjälpte det inte. fortfarande ingen ordinarie bild visas. d:\clients\min url\wwwroot\images. Denna ligger på internet, har ingen betydelse eller?
Provade att skriva in en bild.jpg i slutet som jag vet ligger där, Men det hjälpet inte heller. Finns det några andra tips om vad det skulle kunna vara som inte funkar?.

//Jocke

Filnamn = "http://www.min url/images/Rst(""bild"")"
sökvägen är inte rätt.

Filnamn = "d:\mapp\undermapp\bilder\" & rst("bild")


ETt tips är att läsa på lite om variabelhantering.

Något åt det här hållet alltså:

<%
	Dim Connect, Rst, filnamn, fso, path

	Path = Server.MapPath("/images/")

	'skapar "FileSystemObject"
	Set fso = server.CreateObject("Scripting.FileSystemObject")
	
	Set Connect = Server.CreateObject("ADODB.Connection")
	Connect.Open "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=" & Server.MapPath("db/db.mdb")	

	sql = "SELECT TOP 5 * FROM objects ORDER BY objectid DESC"

	Set Rst = connect.Execute(sql)

	Do Until Rst.EOF
		'Sökvägen till min  
		Filnamn = Path & Rst("bild")"
		If (fso.FileExists(Filnamn)) then
%>
        <IMG width="50" height="75" SRC="images/<%=Rst("bild")%>"alt="<%=Rst("Title")%>"
<%
		Else
%>
        <IMG width="50" height="75" SRC="images/npa.gif" ></a>
  <%
		End If
		Rst.MoveNext
	loop

	'stänger objecten
	Rst.Close
	Set Rst = Nothing

	Connect.Close
	Set Connect = Nothing

	set fso = nothing
%>

	Path = Server.MapPath("/images/") & "\"

Kanon, Tack så mycket Andreas, Lite smärre justeringar av din kod & den funkar ferfekt.
Tack än en gång.
//Jocke