Hej har ett itet dilemma som jag inte kan lösa. Hämtar en kommaseparerad sträng från db som skall visa lite checkboxar, om boxens nummer finns i db skall den checkas annars skall den vara ocheckad.. så här har jag försökt lösa det vara_size är kommaseparerad från databasen:

I en annan tabell har jag skrivit in alla "boxar" som skall finnas "rs1("storlekar")"
den skriver ut som den ska men det känns som om något är fel, antingen skriver den ut allting dubbelt eller så checkar den bara av 1 enda box... vore skoj att få andra åsikter än mina egna.. hade tänkt att om inte checkboxen finns i den kommaseparerade strängen skall den skriva ut den som ocheckad...

Vet att jag förklarar som ett **hål men gör gärna ett försök jag är tacksam för all hjälp jag kan få.

<%
Dim storlek , i
storlek = Split(rs("vara_size"),",")
For i = 0 To UBound(storlek)
%>

<input type="checkbox" name="size" value="<%=storlek(i)%>" checked><%=storlek(i)%><br>

<% do while not rs1.eof %>

<% if rs1("storlekar") <> storlek(i) then %>

<input type="checkbox" name="size" value="<%=rs1("storlekar")%>"><%=rs1("storlekar")%><br>

<% else %>

<% end if %>

<% rs1.movenext:loop %>

<% Next %>

Du kan skriva något sånt här:

<%
     Dim storlek
     storlek = Split(rs("vara_size"),",")

     'rs1.MoveFirst
     Do Until rs1.eof 
         If Exist(rs1("storlekar"), storlek) then
             checked = "checked=""checked"""
         Else
             checked = ""
         End If
%>
<input type="checkbox" name="size" value="<%=rs1("storlekar")%>" <%=checked%>><%=rs1("storlekar")%><br>
<% 
         rs1.movenext
     Loop

Function Exist(Value, Values)
Dim tmp
    Exist = False
    For Each tmp in Values
        If tmp = Value Then
            Exist = True
            Exit For
        End If
    Next
End Function
%>

Funkade super, du är min alldeles egna Jultomte från nu. Tack sååå mycket för hjälpen.