Jag har en variabel som heter inloggmin
Den vissar tiden sedan någon loggade in i minuter, men ibland bli det några tusen minuter, kan man skriva det som
2 timmar och 23 min (om det är över 59 min)
Och 3 dagar 4 timmar och 39 min (om det är över 24 timmar)?

Detta kanske är en början.
<code>
Public Function NiceTime(Minutes)
Dim Days
Dim Hours
Days = Minutes \ 1440
Minutes = Minutes Mod 1440
Select Case Days
Case 0
Case 1
NiceTime = "1 dag "
Case Else
NiceTime = Days & " dagar "
End Select

Hours = Minutes \ 60
Minutes = Minutes Mod 60
Select Case Hours
Case 0
Case 1
NiceTime = NiceTime & "1 timme "
Case Else
NiceTime = NiceTime & Hours & " timmar "
End Select

Select Case Minutes
Case 0
Case 1
NiceTime = NiceTime & "1 minut "
Case Else
NiceTime = NiceTime & Minutes & " minuter "
End Select
End Function
</code>

Ja, den var ju godkänd faktiskt, tackar så mycket!
PS. Även om den inte skriver ut det så snyggt, föredrar ju några "och" här och där, men det ska jag pilla in själv :) .DS.

Något som det här?:
<code>
Public Function NiceTime(Minutes)
Dim Weeks
Dim Days
Dim Hours
Dim Count
Dim Parts()
Weeks = Minutes \ 10080
Minutes = Minutes Mod 10080
If Weeks Then
ReDim Preserve Parts(Count)
If Weeks = 1 Then
Parts(Count) = "1 vecka"
Else
Parts(Count) = Weeks & " veckor"
End If
Count = Count + 1
End If

Days = Minutes \ 1440
Minutes = Minutes Mod 1440
If Days Then
ReDim Preserve Parts(Count)
If Days = 1 Then
Parts(Count) = "1 dag"
Else
Parts(Count) = Days & " dagar"
End If
Count = Count + 1
End If

Hours = Minutes \ 60
Minutes = Minutes Mod 60
If Hours Then
ReDim Preserve Parts(Count)
If Hours = 1 Then
Parts(Count) = "1 timme"
Else
Parts(Count) = Hours & " timmar"
End If
Count = Count + 1
End If

If Minutes Then
ReDim Preserve Parts(Count)
If Minutes = 1 Then
Parts(Count) = "1 minut"
Else
Parts(Count) = Minutes & " minuter"
End If
Count = Count + 1
End If
If Count Then
NiceTime = Parts(Count - 1)
If Count > 1 Then
ReDim Preserve Parts(Count - 2)
NiceTime = Join(Parts, ", ") & " och " & NiceTime
End If
End If
End Function
</code>

jag gör en loop, och då skriver den ut:
5 minuter
5 minuter, 10 timmar och 29 minuter
5 minuter, 10 timmar, , 12 timmar och 21 minuter
5 minuter, 10 timmar, , 12 timmar, , 13 timmar och 16 minuter
5 minuter, 10 timmar, , 12 timmar, , 13 timmar, , 19 timmar och 24 minuter

Vilken är det jag ska nollställa mellan varje loop?
Som det är nu så nollställer jag Minutes, och jag prövade att nolla Parts också, men då skrev den inte ut nåt...
Jag gör säkert fel med, använder inte delen "Function", för jag förstår inte hur jag ska göra, jag skriver bara såhär:

<code>
'Public Function NiceTime(Minutes)
Weeks = Minutes \ 10080
Minutes = Minutes Mod 10080
If Weeks Then
ReDim Preserve Parts(Count)
If Weeks = 1 Then
Parts(Count) = "1 vecka"
Else
Parts(Count) = Weeks & " veckor"
End If
Count = Count + 1
End If

Days = Minutes \ 1440
Minutes = Minutes Mod 1440
If Days Then
ReDim Preserve Parts(Count)
If Days = 1 Then
Parts(Count) = "1 dag"
Else
Parts(Count) = Days & " dagar"
End If
Count = Count + 1
End If

Hours = Minutes \ 60
Minutes = Minutes Mod 60
If Hours Then
ReDim Preserve Parts(Count)
If Hours = 1 Then
Parts(Count) = "1 timme"
Else
Parts(Count) = Hours & " timmar"
End If
Count = Count + 1
End If

If Minutes Then
ReDim Preserve Parts(Count)
If Minutes = 1 Then
Parts(Count) = "1 minut"
Else
Parts(Count) = Minutes & " minuter"
End If
Count = Count + 1
End If
If Count Then
NiceTime = Parts(Count - 1)
If Count > 1 Then
ReDim Preserve Parts(Count - 2)
NiceTime = Join(Parts, ", ") & " och " & NiceTime
End If
End If
'End Function
</code>

Hur ska jag sätta in variabeln "inloggmin" i den funktionen?

Jag förstår inte buggen heller...?
Mellan noll och ungefär 20-30 min så står det:
"Loggade in för minuter sen!"(???)

Jag får inget av dina fel. Är nog du som har gjort något konstigt. Testa följande:
<code>
<%
Function NiceTime(Minutes)
Dim Weeks
Dim Days
Dim Hours
Dim Count
Dim Parts()
Weeks = Minutes \ 10080
Minutes = Minutes Mod 10080
If Weeks Then
ReDim Preserve Parts(Count)
If Weeks = 1 Then
Parts(Count) = "1 vecka"
Else
Parts(Count) = Weeks & " veckor"
End If
Count = Count + 1
End If

Days = Minutes \ 1440
Minutes = Minutes Mod 1440
If Days Then
ReDim Preserve Parts(Count)
If Days = 1 Then
Parts(Count) = "1 dag"
Else
Parts(Count) = Days & " dagar"
End If
Count = Count + 1
End If

Hours = Minutes \ 60
Minutes = Minutes Mod 60
If Hours Then
ReDim Preserve Parts(Count)
If Hours = 1 Then
Parts(Count) = "1 timme"
Else
Parts(Count) = Hours & " timmar"
End If
Count = Count + 1
End If

If Minutes Then
ReDim Preserve Parts(Count)
If Minutes = 1 Then
Parts(Count) = "1 minut"
Else
Parts(Count) = Minutes & " minuter"
End If
Count = Count + 1
End If
If Count Then
NiceTime = Parts(Count - 1)
If Count > 1 Then
ReDim Preserve Parts(Count - 2)
NiceTime = Join(Parts, ", ") & " och " & NiceTime
End If
End If
End Function


Dim M

For M = 1 to 500 Step 5
Response.Write NiceTime(M) & "<BR>" & vbCrLf
Next
%>

</code>