Har en funktion som kollar om en sträng är längre än 22 tecken och om den är det så ska den lägga in en radbrytning (chr(10) ) på lämpligt ställe...kan dock inte komma på hur jag ska lösa detta.

1. Vad är vb-motsvarigeten för mellanslag, går ju inte att skriva
chr(0) utan man vill skriva ngt i stil med vbCrLf.

Min påbörjade funktion:
------------------------------------
strMessage="Hej alla glada människor, detta kanske funkar ?"

if len(strMessage)=>22 then

Replace(strMessage, chr(0), chr(10), 30, 1, vbTextCompare)
else
response.write "Mindr än 42"
end if

------------------

Mellanslag kan du skriva som " " eller Chr(32)

/Johan

Vet inte om det är så här du menar:
<code>
Function BreackMessage(Value, Length)
Dim Pos
Dim Temp
Dim Char
Dim Chars
Dim CharLen
Dim Result
Dim Message
Chars = Array(vbCrLf, ".", ",", "!", "?", " ")
Message = Value
Do While Len(Message) > Length
Temp = Left(Message, Length)
For Each Char In Chars
Pos = InStrRev(Temp, Char)
If Pos Then Exit For
Next
If Pos Then
CharLen = Len(Char)
Result = Result & Left(Temp, Pos + CharLen - 1) & vbCrLf
Message = LTrim(Mid(Message, Pos + CharLen))
Else
Result = Result & Temp & vbCrLf
Message = LTrim(Mid(Message, Length))
End If
Loop
BreackMessage = Result & Message
End Function

BreackMessage("Hej alla glada människor, detta kanske funkar? Frågan är bara hur det ska fungera? Skall den bryta på mellanslag eller skiljetecken?",42)
</code>

Ger:
<code>
Hej alla glada människor,
detta kanske funkar?
Frågan är bara hur det ska fungera?
Skall den bryta på mellanslag eller
skiljetecken?
</code>

Jodå precis så jag vill att det ska fungera...tack så mycket ! Kom en bit på vägen igår...dock inte så långt som ditt exempel.

Tack för hjälpen !