Detta script har jag hittat här på Pellesoft, men jag hittar det inte i forumet igen och kan ej få det att fungera. Någon som kan se var felet ligger.
Det går inte att logga in med anv: admin och lösen: admin.
På nåt sätt så tar inte scriptet hand om mina inmatade värden enl Pelle(sysop)


<%
'Av Gunnar Liljas, 2001 - gunnar@leon.se
'Ovanst&#314;ende rad ska vara kvar, om du använder skriptet
'Funktionen CheckUser byts ut mot godtycklig användarkoll, och självklart kan man kolla n&#314;got annat än Session("UserID")

DoAuth

Response.Write "det funkade"

Sub DoAuth
if isempty(Session("UserID")) then
strAuth=request.servervariables("HTTP_AUTHORIZATION")


'response.write strAuth: response.end

if len(strAuth)>7 then
if lcase(left(strAuth,5))="basic" then
strAuth=mid(strAuth,7)
strAuth=Base64Decode(strAuth)
arrLogin=split(strAuth,":")
strUser=arrLogin(0)
strPass=arrLogin(1)
if CheckUser(strUser,strPass) then
exit sub
end if
end if
end if

NoAuth
end if
End Sub

Function CheckUser(username,password)
if username="admin" and password="admin" then
Session("UserID")=1
CheckUser=true
end if
End Function

Sub NoAuth
Response.Status = "401 Unauthorized"
Response.AddHeader "WWW-Authenticate","BASIC Realm=Min skyddade zon"
Response.Write "<B>Fy skäms!</B>"
Response.End
End Sub

Function Base64Decode(inString)
dim strOutput,intPos,intCharPos,intBytes,intTmpPos,intTmp,strChar
CONST Base64Chars = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/"
if (Len(inString) mod 4)<>0 then exit function
for intPos=1 to Len(inString) step 4
intBytes=3
intTmp=0
for intCharPos=0 to 3
if mid(inString, intPos + intCharPos, 1) = "=" then
intBytes=intBytes-1
intTmpPos=0
else
intTmpPos=InStr(Base64Chars, Mid(inString, intPos + intCharPos, 1)) - 1
if intTmpPos=-1 then exit function
end if
intTmp=64*intTmp+intTmpPos
next
for intCharPos=1 to intBytes
select case intCharPos
case 1:
strOutput=strOutput & chr(intTmp \ 65536)
case 2:
strOutput=strOutput & chr((intTmp and 65535) \ 256)
case 3:
strOutput=strOutput & chr(intTmp and 255)
end select
next
next
Base64Decode = strOutput
End Function

%>

För att det ska fungera så
måste du stänga av Autensieringen i
IIS:en, då ska det fungera med en
egen NT-Login, dock så
vet jag inte vart man stänger av den
i IIS:en och kan inte kolla för
att jag valt att inte installera IIS.

Hur gör man om man har PWS då? Där finns väl inga såna inställningar....eller?