Hej!
Har en mdb-fil som innehåller en tabell (tdjp)
innehåller; ID (räknare), Vecka (Text), Placering (text), Artist (text), Lat (text), InlagtDatum (datum).

Vill gärna ha hjälp med en asp sida (eller tankegång) hur jag skall göra för att kunna ta fram rapport rapport för vecka (Vecka)
Tanken är att ha en asp-sida som skapar en "select" av veckorna men sen är det stopp då jag är helt nybörjare på det här med asp.

En mycket tacksam DJ! ;-)

Mvh tyrone

Vet inte riktigt hur du menar men vi börjar så här så får du prova dig lite fram och berätta varifrån du vill gå med hjälp av denna kod
<code>
' öppna connection till databasen
Dim dbConn
set dbConn = server.CreateObject("ADODB.Connection")

strCon = "Provider=Microsoft.Jet.OLEDB.4.0;" &_
"Data Source=" & server.MapPath("dj.mdb") & ";" &_
"Persist Security Info=False"
dbConn.ConnectionString = strCon
dbConn.open

' välja tabell från databasen
set rs = dbConn.execute("SELECT * FROM tdjp ORDER BY ID ASC")

' kolla så att det finns poster
If not (rs.bof OR rs.eof) then

' loopa igenom allt innehåll i tabellen
Do until rs.eof
Response.Write(rs("vecka") & " - " & rs("Artist")) ' exempelvis
rs.movenext
Loop

' om det inte finns något i tabellen
else
Response.Write("Det finns ingen data i denna tabell")

end if

' stänga alla databas connections
rs.close
set rs = nothing
dbConn.close
set dbConn = nothing
</code>

Som sagt, börja med detta och fråga sen när du testat dig lite fram
lycka till!

// eric

<code>
<FORM action="" method=post>
<SELECT name="Vecka">
<OPTION Value=""> - Välj en vecka - </OPTION>
<%
Dim rs
Dim con
Dim strCon

' öppna connection till databasen
strCon = "Provider=Microsoft.Jet.OLEDB.4.0;" &_
"Data Source=" & server.MapPath("dj.mdb") & ";" &_
"Persist Security Info=False"

Set con = Server.CreateObject("ADODB.Connection")
con.open strCon

' välja tabell från databasen
Set rs = Server.CreateObject("ADODB.Recordset")
rs.Open "SELECT vecka FROM tdjp GROUP BY vecka", con

Do Until rs.EOF
If rs("vecka") = Request.Form("Vecka") Then
%>
<OPTION selected><%=Server.HTMLEncode(rs("vecka"))%></OPTION>
<%
Else
%>
<OPTION><%=Server.HTMLEncode(rs("vecka"))%></OPTION>
<%
End If
rs.MoveNext
Loop
rs.Close
%>
</SELECT>
<INPUT type=submit value="Uppdatera" name="Action">
</FORM>
<B>Vecka: </B><%=Server.HTMLEncode(Request.Form("Vecka"))%><BR>
<BR>
<TABLE border=0>
<TR>
<TD><B>Placering</B></TD>
<TD><B>L&aring;t</B></TD>
<TD><B>Artist</B></TD>
</TR>
<%
rs.Open "SELECT * FROM tdjp WHERE vecka = '" & Replace(Request.Form("Vecka"), "'", "''") & "' ORDER BY Placering", con

Do Until rs.EOF
%>
<TR>
<TD><%=Server.HTMLEncode(rs("Placering"))%></TD>
<TD><%=Server.HTMLEncode(rs("Lat"))%></TD>
<TD><%=Server.HTMLEncode(rs("Artist"))%></TD>
</TR>
<%
rs.MoveNext
Loop

rs.Close
set rs = nothing

con.close
set con= nothing
%>
</TABLE>
</code>