Jag läste en artikel om att hämta information från ett excel ark men jag får det inte att fungera. Artikeln heter "Hämta och visa data från ett Excelark som databas"
Till att börja med vet jag inte vilket versions nr jag ska använda när jag använder mig av Excel XP.

<code>
<%
set objconn=server.CreateObject("adodb.connection")
strconn = "Provider=Microsoft.Jet.OLEDB.4.0;"&_
"Data Source=C:\WINDOWS\Skrivbord\ny_alltidata\db\NyaPriser\writefile.xls;"&_
"Extended properties=""Exel 8.0;HDR=YES;"";"

response.write strconn


objconn.open strconn



' set ObjRS=objconn.Execute("select A, B, C from [blad1$]")

' response.write objRS("A")


%>
</code>


Jag får ett felmeddelande:

Provider=Microsoft.Jet.OLEDB.4.0;Data Source=C:\WINDOWS\Skrivbord\ny_alltidata\db\NyaPriser\writefile.xls;Extended properties="Exel 8.0;HDR=YES;";
Microsoft JET Database Engine fel '80004005'

Det går inte att hitta installerbar ISAM.

/webmaster/nya_priser/test.asp, rad 10


Snälla någon HJÄLP!

Tack på förhand
Mvh Fredde

Filen som du ska läsa ifrån borde ligga på servern, det gör den inte här. Du har även angett att du har en header i dokumentet, men du hämtar A, B, C då ska HDR vara NO
<code>
<%
Dim Conn, strConn, RS
Dim i, varArray
Set Conn=Server.CreateObject("ADODB.Connection")

strConn = "Provider=Microsoft.Jet.OLEDB.4.0;" & _
"Data Source = " & Server.MapPath("dinExcelFil.xls") & ";" & _
"Extended Properties=""Excel 8.0;HDR=Yes;"";"

Conn.open strConn

Set RS=Conn.Execute("SELECT Kolumn1, Kolomn2, Kolumn3, Kolumn4, Kolumn5, Kolumn6 FROM [dittDatablad$]")

varArray = RS.GetRows()
RS.Close
Set RS = Nothing
Conn.Close
Set Conn = Nothing

For i = 0 to UBound(varArray,2)
Response.Write "Kol1=" & varArray(0,i) & " : Kol2=" & varArray(1,i) & " : Kol3=" & varArray(2,i) & " : Kol4=" & varArray(3,i) & " : Kol5=" & varArray(4,i) & " : Kol6=" & varArray(5,i) & "<br>"
Next
%>
</code>

Om du får felet "Det går inte att hitta installerbar ISAM" så beror det troligen på att du inte har Jet 4.0 installerad på din server. Du finner en länk till den via systemdokument/servicepacks här på pellesoft.

Tack för svaret!
Jag har provat att uppdatera till JET 4,0 men det hjälpte inte.

Jag får fortfarnde inte det att fungera, du kan se felmeddelandet nedan.

Microsoft JET Database Engine fel '80040e10'

Det har inte angetts något värde för en eller flera nödvändiga parametrar.


<code>
<%
Dim Conn, strConn, RS
Dim i, varArray
Set Conn=Server.CreateObject("ADODB.Connection")

strConn = "Provider=Microsoft.Jet.OLEDB.4.0;" & _
"Data Source = " & Server.MapPath("writefile.xls") & ";" & _
"Extended Properties=""Excel 8.0;HDR=no;"";"

Conn.open strConn


Rad 12:
Set RS=Conn.Execute("SELECT a, b, c, d, e FROM [blad1$]")


varArray = RS.GetRows()
RS.Close
Set RS = Nothing
Conn.Close
Set Conn = Nothing

For i = 0 to UBound(varArray,2)
Response.Write "Kol1=" & varArray(0,i) & " : Kol2=" & varArray(1,i) & " : Kol3=" & varArray(2,i) & " : Kol4=" & varArray(3,i) & " : Kol5=" & varArray(4,i) & " : Kol6=" & varArray(5,i) & "<br>"
Next
%>

</code>

Mvh Fredrik

Bra, då ökar förutsättningarna. Har du läst excelkursen jag skrivit här om hur man med asp hämtar data? Den kanske hjälper dig.

Hej Hej!

Jag har läst kursen/artikeln som heter "Hämta och visa data från ett Excelark som databas" någon annan artikel hittar jag inte.

Jag ska läsa genom den igen för att se om jag missat något.

Mvh Fredde

Istället för att använda excel:s cellnamn a, b, c, d osv. så skriv in ett namn i varje kolumn, ungefär så här:
<code>
a b osv.
1 FörNamn EfterNamn
2 Kalle Karlsson
3 Peter Svensson
4 Jan Banan
5 Ola Bandola
osv.
</code>

<code>
<%
Dim Conn, strConn, RS
Dim i, varArray
Set Conn=Server.CreateObject("ADODB.Connection")

strConn = "Provider=Microsoft.Jet.OLEDB.4.0;" & _
"Data Source = " & Server.MapPath("writefile.xls") & ";" & _
"Extended Properties=""Excel 8.0;HDR=YES;"";"

Conn.open strConn

Set RS=Conn.Execute("SELECT ForNamn, EfterNamn FROM [blad1$]")'Namnet på bladet i ditt exceldokument


varArray = RS.GetRows()
RS.Close
Set RS = Nothing
Conn.Close
Set Conn = Nothing

For i = 0 to UBound(varArray,2)
Response.Write "Kol1=" & varArray(0,i) & " : Kol2=" & varArray(1,i) & "<br>"
Next
%>

</code>

Nu fungerar det!

Tack för hjälpen!

Mvh Fredrik