Hej!
Håller på med en anmälnings sida med 30 deltagare, om det anmäler sig mer än 30 så skall dom komma i en reservlista, Hur gör man så?. Lite kod

sql = "SELECT Top 30 * FROM boka"
Set RecSet = connect.Execute(sql)
Do until RecSet.EOF
%>
<tr>
<td><%response.write RecSet("name")%>&nbsp;</td>
<td><%response.write RecSet("nick")%>&nbsp;</td>
<td><%response.write RecSet("mat")%>&nbsp;</td>
<td align="center"><font color="ffffff"><%response.write RecSet("betalat")%>&nbsp;</td>
</tr>
<%
RecSet.MoveNext
Loop

%>
Ovanstående fungerar, men det är reservlistan som spökar.
Hur ser sql strängen ut till detta? Jag har följande som inte fungerar.
<!--reservlistan här nedan-->
<tr><td colspan="4" align="center"><i><font color="ffffff">Följande ligger på reserv Listan</font></i></td></tr>
<%
SQL2 = "SELECT * FROM boka"
Set Recset2 = connect.Execute(SQL2)
For i=1 TO 30
Next
%>
<tr>
<td><%response.write (RecSet2("name"))%> &nbsp;</td>
<td><%response.write (RecSet2("nick"))%> &nbsp;</td>
<td><%response.write (RecSet2("mat"))%> &nbsp;</td>
<td align="center"><font color="ffffff"><%response.write (RecSet2("betalat"))%></font>&nbsp;</td>
</tr>
<%
Do until RecSet2.EOF
RecSet2.MoveNext
Loop
Set Connect = Nothing
%>
Säkert skitenkelt när man kan det, fast nu har jag kört fast ordentligt.
//Jocke

gör en till kolumn som heter reserv där värdet antingen är true eller false sen en select som räknar poster som har false i reserv är det 30 så sparas posten som true i reserv

Jag har 4 kollumer i bredd som skriver ut infon om deltagaren. Denna lista blir längre och längre ju mer som anmält sig. Som koden visar så vill jag ha det efter den ordinarie listan och inte en ny kollumn. Kan du ge mig lite kod exempel om true eller false, allt finns i min kod här ovan.

Det enklaste är väl att loopa ur samma recordset:
<code>
<table>
<%
Dim strSQL
Dim Index
Dim RecSet
Dim Connect

Set Connect = Server.CreateObject("ADODB.Connection")
Connect.Open ">>>Din anslutningssträng<<<"

strSQL = "SELECT * FROM boka"
Set RecSet = Server.CreateObject("ADODB.Recordset")
RecSet.Open strSQL, Connect

Do until RecSet.EOF Or Index >= 30
Index = Index + 1
%>
<tr>
<td><%Response.Write RecSet("name")%>&nbsp;</td>
<td><%Response.Write RecSet("nick")%>&nbsp;</td>
<td><%Response.Write RecSet("mat")%>&nbsp;</td>
<td align="center"><font color="ffffff"><%response.write RecSet("betalat")%></font>&nbsp;</td>
</tr>
<%
RecSet.MoveNext
Loop

If Not RecSet.EOF Then
%>
<!--reservlistan här nedan-->
<tr><td colspan="4" align="center"><i><font color="ffffff">Följande ligger på reserv Listan</font></i></td></tr>
<%
Do
%>
<tr>
<td><%response.write (RecSet("name"))%> &nbsp;</td>
<td><%response.write (RecSet("nick"))%> &nbsp;</td>
<td><%response.write (RecSet("mat"))%> &nbsp;</td>
<td align="center"><font color="ffffff"><%response.write (RecSet("betalat"))%></font>&nbsp;</td>
</tr>
<%
RecSet.MoveNext
Loop Until RecSet.EOF
End If

RecSet.Close
Set RecSet = Nothing

Connect.Close
Set Connect = Nothing
%>
</table>
</code>

Tack för detta, Hör av mig om det inte funkar.
//Jocke

Inte mitt problem om den inte funkar.
Alla förslag lämnas utan garanti. :P

Hej igen!
Nej jag vet att det inte är ditt problem om det inte funkar, Men denna gången gjorde det det. Fungerar klockrent. Det är som på jobbet, när man lagat något så lämmnar jag bara RH garanti. "Runt Hörnet" garati. 8-)
Tack för mig
//Jocke

Får jag fråga när du ska bli bonusmedlem?

Jag var bonusmedlem förra året, men jag har inte hunnit betala in ännu.