Hej jag får ett fel i min sql sats.
Nu skriver jag vad alla olika kolumner har för tabell typer kan ju underlätta en del.

Namn = Text
Epost = Text
Rubrik = Text
Inlagg = PM
Datum = Datum/Tid
Category = tal
Org = tal
Losen = Text
senast = Datum/tid

Och här är felmedelandet.

Feltyp:
Microsoft OLE DB Provider for ODBC Drivers (0x80040E07)
[Microsoft][Drivrutin för ODBC Microsoft Access] Typblandningsfel i villkorsuttryck.
/inc/forum/forum_start.asp, line 36


och här är rad 36.
con.execute(sql)


Och här kommer det intresanta koden.

rubrik=Request.form("rubrik")
inlagg=Request.form("inlagg")
epost=Request.form("epost")
namn=Request.form("namn")
datum=now
ip=Request.ServerVariables("REMOTE_ADDR")
losen=Request.form("losen")
org=1
category=Request.form("category")
senast=now
sql = "INSERT INTO forumInlagg"
sql = sql & "(rubrik, inlagg, epost, namn, datum, ip, losen, org, category, senast)"
sql = sql & "Values ('" & rubrik & "','" & inlagg & "','" & epost & "','" & namn & "',' & datum & ','" & ip & "','" & losen & "',' & org & ',' & category & ',' & senast & ')"
con.execute(sql)

Prova med att sätta # innan och efter alla datumvärden, typ:

rubrik=Request.form("rubrik")
inlagg=Request.form("inlagg")
epost=Request.form("epost")
namn=Request.form("namn")
datum=now
ip=Request.ServerVariables("REMOTE_ADDR")
losen=Request.form("losen")
org=1
category=Request.form("category")
senast=now
sql = "INSERT INTO forumInlagg"
sql = sql & "(rubrik, inlagg, epost, namn, datum, ip, losen, org, category, senast)"
sql = sql & "Values ('" & rubrik & "','" & inlagg & "','" & epost & "','" & namn & "',#' & datum & '#,'" & ip & "','" & losen & "',' & org & ',' & category & ',#' & senast & '#)"
con.execute(sql)

hopp....de gick ej

Microsoft OLE DB Provider for ODBC Drivers (0x80040E14)
[Microsoft][Drivrutin för ODBC Microsoft Access] Syntaxfel i datum i frågeuttrycket '#' & datum & '#'.

datumfält ska enbart ha #
ingen ' ska finnas där

Får ändå de här felet

Microsoft OLE DB Provider for ODBC Drivers (0x80040E14)
[Microsoft][Drivrutin för ODBC Microsoft Access] Syntaxfel i datum i frågeuttrycket '# & datum & #'.
/inc/forum/forum_start.asp, line 34

Prova med: #" & Now() & "#

som jag sa
det ska _INTE_ vara nåt ' med i datumfälten

Testa med:
<code>
Function SQLText(Value)
If Len(Value) > 0 Then
SQLText = "'" & Replace(Value, "'", "''") & "'"
Else
SQLText = "Null"
End If
End Function

Function SQLDate(Value)
If IsDate(Value) Then
SQLDate = "#" & Value & "#"
Else
SQLDate = "Null"
End If
End Function

rubrik=Request.form("rubrik")
inlagg=Request.form("inlagg")
epost=Request.form("epost")
namn=Request.form("namn")
datum=now
ip=Request.ServerVariables("REMOTE_ADDR")
losen=Request.form("losen")
org=1
category=Request.form("category")
senast=now

strSQL = "INSERT INTO forumInlagg (rubrik, inlagg, epost, namn, datum, ip, losen, org, category, senast)" & vbCrLf & _
"VALUES (" & SQLText(rubrik) & "," & SQLText(inlagg) & "," & SQLText(epost) & "," & SQLText(namn) & ", " & SQLDate(datum) & "," & SQLText(ip) & "," & SQLText(losen) & "," & SQLText(org) & "," & SQLText(category) & "," & SQLDate(senast) & ")"
con.execute strSQL
</code>

category är ju ett tal, ska det verkligen läsas in som en SQLText och få fnuttar på sig!?

Skippa det och kör en CInt(category) istället för SQLText(category) är mitt förslag

Lite reviderad:
<code>
Function SQLText(Value)
If Len(Value) > 0 Then
SQLText = "'" & Replace(Value, "'", "''") & "'"
Else
SQLText = "Null"
End If
End Function

Function SQLDate(Value)
If IsDate(Value) Then
SQLDate = "#" & Value & "#"
Else
SQLDate = "Null"
End If
End Function

Function SQLNumber(Value)
If IsNumeric(Value) Then
SQLNumber = Replace(Value,",",".")
Else
SQLNumber = "Null"
End If
End Function


rubrik=Request.form("rubrik")
inlagg=Request.form("inlagg")
epost=Request.form("epost")
namn=Request.form("namn")
datum=now
ip=Request.ServerVariables("REMOTE_ADDR")
losen=Request.form("losen")
org=1
category=Request.form("category")
senast=now

strSQL = "INSERT INTO forumInlagg (rubrik, inlagg, epost, namn, datum, ip, losen, org, category, senast)" & vbCrLf & _
"VALUES (" & SQLText(rubrik) & "," & SQLText(inlagg) & "," & SQLText(epost) & "," & SQLText(namn) & ", " & SQLDate(datum) & "," & SQLText(ip) & "," & SQLText(losen) & "," & SQLNumber(org) & "," & SQLNumber(category) & "," & SQLDate(senast) & ")"
con.execute strSQL

</code>

alltid lika lysande kodexempel Andreas, lyfter på hatten.

Pedagogiska och överskådliga, tjusigt..

Man tackar för komplimangen.