Hej

Hur får man fram den där Bläddra-boxen där man kan välja mapp för installationer m.m.? Såg nånstans hur man kunde få fram den med API eller vad det nu var.

Tack på förhand.

/Tobbe
http://taxen.cjb.net

Det beror på vad du programmerar i.
Är det i VB så finns det massvis med komponenter som gör just det.
Det vanligaste sättet är att välja Add Component - Microsoft Common Dialog. Sedan placerar du "kontrollen" i ditt fomulär. Testa dig fram med vad du skall göra med den.

'Include this code in an code module
Option Explicit

'---------------------------------------------------
' WinAPI Declarations
'---------------------------------------------------
Private Declare Sub CoTaskMemFree _
Lib "ole32.dll" ( _
ByVal hMem As Long _
)
Private Declare Function SHBrowseForFolder _
Lib "shell32" ( _
lpbi As BrowseInfo _
) As Long
Private Declare Function SHGetPathFromIDList _
Lib "shell32" ( _
ByVal pidList As Long, _
ByVal lpBuffer As String _
) As Long
Private Declare Function GetActiveWindow _
Lib "user32" ( _
) As Long

'-------------------------------------------------
' User-Defined Types
'-------------------------------------------------
Private Type BrowseInfo
hwndOwner As Long
pIDLRoot As Long
pszDisplayName As String
lpszTitle As String
ulFlags As Long
lpfnCallback As Long
lParam As Long
iImage As Long
End Type

'-------------------------------------------------
' Module-level Constants
'-------------------------------------------------
'used for SHBrowseForFolder APIs
Const BIF_RETURNONLYFSDIRS = 1
Const MAX_PATH = 260

Function BrowseForFolder() As String
Dim iNull As Integer
Dim lpIDList As Long
Dim lResult As Long
Dim sPath As String
Dim udtBI As BrowseInfo

With udtBI
.hwndOwner = GetActiveWindow&
.lpszTitle = "Choose a folder"
.ulFlags = BIF_RETURNONLYFSDIRS
End With

lpIDList = SHBrowseForFolder(udtBI)
If lpIDList Then
sPath = String$(MAX_PATH, 0)
lResult = _
SHGetPathFromIDList _
(lpIDList, sPath)
Call CoTaskMemFree(lpIDList)
iNull = InStr(sPath, _
vbNullChar)
If iNull Then _
sPath = Left$(sPath, iNull - 1)
End If
BrowseForFolder = sPath
End Function

Du kan testa med detta.

Leif P