En liten fråga till ett troligtvis simpelt problem

När man spelar in ett makro för att dra en linje i powerpoint så ser koden ut enl följande

ActiveWindow.Selection.SlideRange.Shapes.AddLine(120#, 270#, 372#, 270#).Select

Nu vill jag istället kunna, antingen peka ut (Med musklick) start och slutpunkt alt.
Ange start och slutpunktskoordinater med hjälp av en Inputbox motsv.
Kan någon hjälpa mig med detta???

Jörgen P

Med musklick vet jag inte riktigt, men om du kan tänka dig att ange koordinaterna så kan du göra någonting i den här stilen:

<code>
Sub InfogaLinje()
Dim sReturn As String
Dim lIdx As Long
Dim vntMeasures As Variant
Const POINTSPERCM As Currency = 28.3465

sReturn = InputBox("Ange koordinater i cm för linjen enligt formatet:" _
& vbCr & vbCr & "StartX;StartY;SlutX;SlutY", "Infoga linje")

vntMeasures = Split(sReturn, ";")

With ActiveWindow.Selection
If UBound(vntMeasures) = 3 Then
For lIdx = 0 To 3
If Not IsNumeric(vntMeasures(lIdx)) Then
GoTo OgiltigaKoordinater
End If
Next lIdx
Else
GoTo OgiltigaKoordinater
End If

.SlideRange(1).Shapes.AddLine(vntMeasures(0) * POINTSPERCM, _
vntMeasures(1) * POINTSPERCM, vntMeasures(2) * POINTSPERCM, _
vntMeasures(3) * POINTSPERCM).Select
End With

Exit Sub

OgiltigaKoordinater:
MsgBox "Linje kunde inte infogas eftersom koordinaterna var felaktiga.", _
vbExclamation, "Infoga linje"
End Sub

</code>

Jättemånga tack, fungerar finfint.
Riktigt smaskigt hade det trots allt varit om man kan "klicka ut" start och slutkoordinaterna.
Jag tror att jag får skapa en ny fråga och se om svaret på den frågan finns

Än en gång, tusen tack

Jörgen P