Har problem med utskrift i VB6. Har byggt ett fakturaprogram men kan inte få beloppen snyggt högerställda,dom envisas att vara vänterställda. Hoppas på hjälp

Ämnet var uppe för ett tag sedan här men jag hittar inte på det igen.

Du skall använda Tab(antal tecken). Ex.
Du vill att beloppen alltid skall komma/börja på plats 70 på ett A4.
Du vill att beloppfältet skall vara 9 tecken. du vill skriva ut högerställt 47:50 (5 tecken)

Då blir det fritt ur minnet Tab(79 - Len("47:50"))
<code>
Printer.Print;Tab(70 + 9 - Len(talet));talet ' talet är i mitt exempel nämnda 47:50
'---------------
'--------------
Printer.EndDoc
</code>

Tack så hemskt mycket!!!
Lösningen är ju logisk men ibland fungerar inte huvudet...

Osäker nu jaaa Sven, funkar metoden oavsett om man använder teckensnitt med fast bredd
eller TT-snitt ?

Ett alternativ kan kanske vara

<code>
Option Explicit

Const RIGHTMARGIN = 185
Const TOPMARGIN = 25

Private Sub Form_Load()
Dim i As Integer
Dim radsumma(1 To 5) As Currency
Dim sum As Currency
radsumma(1) = 47.5
radsumma(2) = 139.8
radsumma(3) = 2138.1
radsumma(4) = 19.9
radsumma(5) = 68.8

Printer.Scale (0, 0)-(210, 297) 'A4
Printer.ScaleMode = vbMillimeters 'Millimeter
Printer.CurrentY = TOPMARGIN
For i = 1 To 5
Printer.CurrentX = RIGHTMARGIN - Printer.TextWidth(Format(radsumma(i), "##,##0.00"))
Printer.Print Format(radsumma(i), "##,##0.00")
sum = sum + radsumma(i)
Next i
Printer.CurrentX = RIGHTMARGIN - Printer.TextWidth("====================")
Printer.Print "===================="
Printer.CurrentX = RIGHTMARGIN - Printer.TextWidth("Summa: ") - Printer.TextWidth(Format(sum, "##,##0.00"))
Printer.Print "Summa: " & Format(sum, "##,##0.00")
Printer.EndDoc
End Sub
</code>

fast eller kanske inte... ja e lite trött nu så ja kanske bara strular till det ??

[Peter.H]

mmm.... det skall vara TT font, testa med Arial den funkar bra.
Så här skulle jag lösa det.
<code>
'75 får justeras efter koll på första utskrift.
'Kolla med Sans Serif och TT Arial
'Tab tar hänsyn till aktuell FontSize/FontWidth
For i = 1 To 5
Printer.Print ; Tab(75 - Len(Format$(radsumma(i), "##,##0.00"))); radsumma(i)
Sum = Sum + radsumma(i)
Next 'i
</code>

Skall testa din kod på min Printer imorgon och jämföra med mitt förslag.
Jag testar mot Arial 12 Bold och samma sak med Sans Serif 12 Bold.

Var ett tag sedan jag gjorde en snygg PrinterRutin

I sammanhanget kan jag varmt rekommendera denna PDF Printer Driver
som installeras på din maskin och kan användas när man experimenterar med Printrutiner.
http://www.pdf995.com/download.html

Det skapas då ett A4 som .pdf-fil i PDF995 mappen som du sedan kan kolla med Adobe
Kanonbra när man vill spara papper och experimentera.

En variant som inte är så dum är att skicka ut texten i LaTeX-format, sen kompilera LaTeX-en, och få fram en pdf-fil som man slutligen skriver ut. Där är såna här saker i stort sett en barnlek.

Den stora nackdelen är att man får lära sig ett nytt (iofs hyfsat enkelt) språk, och att det blir några extra steg. Själv använder jag aldrig något annat för tekniska rapporter eller annat som måste bli snyggt. För den som är intresserad finns en bra guide på www.dd.chalmers.se/latex/.

Det är en djä.. soppa med Fonter för att få det snyggt.
Detta är det bästa jag lyckades åstadkomma.
<code>
Option Explicit
Const RIGHTMARGIN = 18.5
Const TOPMARGIN = 2.5
Private Sub Command1_Click()
Dim i As Long
Dim radsumma(1 To 5) As Double
Dim sum As Double
Dim tmpRad As String
radsumma(1) = 47.5
radsumma(2) = 139.8
radsumma(3) = 142138.1
radsumma(4) = 19.9
radsumma(5) = 68.8
CmDialog.Flags = &H100000 Or &H4
CmDialog.ShowPrinter
Printer.ScaleMode = 7 'cm
Printer.CurrentY = TOPMARGIN
Printer.FontName = "Arial"
Printer.FontSize = 14
Printer.FontBold = True
'75 får justeras efter koll på första utskrift.
'Kolla med Sans Serif och TT Arial
'Tab tar hänsyn till aktuell Fontwidth
For i = 1 To 5
tmpRad = Format$(radsumma(i), "##,##0.00")
tmpRad = Replace(tmpRad, ",", ":")
Printer.Print ; Tab(75 - Len(tmpRad)); tmpRad
sum = sum + radsumma(i)
Next 'i
Printer.CurrentX = RIGHTMARGIN - _
Printer.TextWidth("====================")
Printer.Print "===================="
Printer.CurrentX = RIGHTMARGIN - 0.9 - _
Printer.TextWidth("Summa: ") - Printer.TextWidth(Format(sum, "##,##0.00"))
tmpRad = Replace(Format$(sum, "##,##0.00"), ",", ":")
Printer.Print "Summa: " & tmpRad
Printer.EndDoc
End Sub
'Din och min lösning ger samma resultat så det är en smaksak hur man gör.
</code>

Hur går det för dig Niklas.Vårterminen är slut,blir det något av dig ?

Ha det
vila hjärnan och ragga brudar dra några bärs och njut av sommaren
SvenPon

<b>>Vårterminen är slut,blir det något av dig ?</b>
Vi får väl se... =)
Sannolikt "Master" i "Komplexa Adaptiva System" så småningom.

<b>>vila hjärnan och ragga brudar dra några bärs och njut av sommaren</b>
Bärsen och hjärnan kan jag lova, men börjar jag ragga blir nog flickvännen sur...

;)