Vad är felet med följande?

Private Sub UpdatePrice(lngID As Long, curNew As Currency)

Dim sSql As String
On Error GoTo ErrH

sSql = "UPDATE Pris SET AkPrice = " & curNew & " Where Akeri > 0 AND CatID =" & lngID
goConn.Execute sSql

Exit Sub
ErrH:
MsgBox "UpdatePrice " & Err.Description
Exit Sub
End Sub

Koden skall uppdatera alla åkeriers priser under en angiven kategori
lngID är kategorien
curNew det nya priset.

MEN - Den genererar ett felmeddelande /Göran

Nr 1 så bör denna rad se ut så här
<code>
Private Sub UpdatePrice(ByVal lngID As Long,ByVal curNew As Currency)
</code>

Har testat, men det fungerar fortfarande inte...

Är curNew ett decimaltal? I sådana fall måste du byta ut , mot . (om du har , som decimaltecken, vilket du troligtvis har).

/Johan

Tack för hjälpen!!

Har precis löst problemet.
Naturligtvis var det kommatecknet som ställde till problemet.

/Göran

Ja detta djä... (,) kommatecken.
För en gång skull så håller jag med "jänkarna".

Decimalavskiljare skall skrivas med (.) Punkt.

Det blev bra i dubbel bemärkelse ;-) .

På enkelska heter det "period" mycket täckande beskrivning.

La in en pedagogisk knorr som gamal lärere jag är.

Ha det
SvenPon

Vill tipsa om command objektet vilket löser dessa problem:

Private Sub UpdatePrice(lngID As Long, curNew As Currency)
Dim cmd As ADODB.Command
On Error GoTo ErrH
    Set cmd = New ADODB.Command
    Set cmd.ActiveConnection = goConn
    cmd.CommandText = "UPDATE Pris SET AkPrice = ?" & vbCrLf & _
                     "WHERE Akeri > 0 AND CatID = ?"
    cmd.Execute , Array(curNew, lngID)
  
   Exit Sub
ErrH:
   MsgBox "UpdatePrice " & Err.Description
   Exit Sub
End Sub

Public Sub UpdatePrice(lngID As Long, curNew As Currency)
Dim cmd As ADODB.Command
On Error GoTo ErrH
    Set cmd = New ADODB.Command
    Set cmd.ActiveConnection = goConn
    cmd.CommandText = "UPDATE Pris SET AkPrice = ?" & vbCrLf & _
                      "WHERE Akeri > 0 AND CatID = ?"
    cmd.Parameters.Append cmd.CreateParameter(, adCurrency, adParamInput, , curNew)
    cmd.Parameters.Append cmd.CreateParameter(, adInteger, adParamInput, , lngID)
    cmd.Execute
  
   Exit Sub
ErrH:
   MsgBox "UpdatePrice " & Err.Description
   Exit Sub
End Sub