Hej hej...
Nu e det så att jag vill bygga en boster till ett spel, en boster är som en autofire till gamla nintendo spel typ.
Den skickar tryckningar till ett ställe så man inte behöver mosa på tangenterna.

Det svåra är inte att skicka tryckningarna utan att få dom att komma rätt.
Hur gör jag för att få tryckningarna att skickas till ett annan fönster typ en webläsare??

Tack för svar // R-mus
P.s jag vet att jag frågade om det här förut, men så försvann alla inlägg, hela forumet faktiskt så nu måste jag fråga om på nytt :) D.s

Hej
Som jag förmodligen svarat innan så kan du använda
App.Activate "Rubriken på webbfönstret"
tex. SendKeys "{ENTER}",True
Du vet förmodligen inte rubriken ,då kan du fånga den
genom att på något sätt vaska fram den ur detta exempel.

Kör detta exempel så du förstår hur jag menar.

'Modul1
Option Explicit
Declare Function EnumWindows Lib "user32" _
(ByVal lpEnumFunc As Long, ByVal lParam As Long) As Boolean

Declare Function GetWindowText Lib "user32" _
Alias "GetWindowTextA" (ByVal hwnd As Long, _
ByVal lpString As String, ByVal cch As Long) As Long

Declare Function GetWindowTextLength Lib "user32" _
Alias "GetWindowTextLengthA" (ByVal hwnd As Long) As Long
Public Function EnumWindowsProc(ByVal hwnd As Long, _
ByVal lParam As Long) As Boolean
Dim sSave As String, ret As Long
ret = GetWindowTextLength(hwnd)
sSave = Space(ret)
GetWindowText hwnd, sSave, ret + 1
Form1.Text1.Text = Form1.Text1.Text _
& CStr(hwnd) _
& " " & sSave _
& vbCrLf
'Kör uppräkning av fönster
EnumWindowsProc = True
End Function

'*********************************
'Form1
'En TextBox Multiline = True ScrollBar Vertical
'En Command1
Option Explicit
Private Sub Command1_Click()
'Anropa Räkana upp aktiva fönster
EnumWindows AddressOf EnumWindowsProc, ByVal 0&
End Sub

återkom så Vi kanske kan lista ut hur du med en if sats
vaskar fram den rubrik du är ute efter,finns kanske
något speciellt kännemärke.

spånar
Sven

det är det här fönstret jag vill åt:
1072 Gladiatorkampen på www.tv4.se - IE_Window_Title

men jag vete f** hur jag ska böra mig åt. och inte heller om fönstret heter samma för varje person.

Skulle man inte kunna lägga till en api funktion som bara skickar tryckningarna till det fönster man väljer efter 3sekunder eller nåt i den stillen, eller ännu bätttre, man kan ju först få välja till vilket fönster man vill skicka tryckningarna ur listan.

Kom just på en ide'....ska nog testa den.
Återkommer med nåt senare // R-mus

Hej
Om det finns ett ord som alltid förekommer i rubriken
kan vi ju söka på det via EnumWindow.

DS

"Gladiator" finns alltid med...

så det skulle man kuna använda....

Tack för hjälpen,(glömde säga det i föra inlägget) // R-mus

Igen
Då kan du använda denna model

'Modul1
Option Explicit
Declare Function EnumWindows Lib "user32" _
(ByVal lpEnumFunc As Long, ByVal lParam As Long) As Boolean

Declare Function GetWindowText Lib "user32" _
Alias "GetWindowTextA" (ByVal hwnd As Long, _
ByVal lpString As String, ByVal cch As Long) As Long

Declare Function GetWindowTextLength Lib "user32" _
Alias "GetWindowTextLengthA" (ByVal hwnd As Long) As Long

Public strGladiator As String

Public Function EnumWindowsProc(ByVal hwnd As Long, _
ByVal lParam As Long) As Boolean
Dim sSave As String, ret As Long
ret = GetWindowTextLength(hwnd)
sSave = Space(ret)
GetWindowText hwnd, sSave, ret + 1
If InStr(sSave, "Gladiator") Then
strGladiator = sSave
End If
'Kör uppräkning av fönster
EnumWindowsProc = True
End Function

'******** Slut Modul1 *****************
'Form1
'En TextBox Multiline = True ScrollBar Vertical
'En Command1
Option Explicit
Private Sub Command1_Click()
'Anropa Räkana upp aktiva fönster
EnumWindows AddressOf EnumWindowsProc, ByVal 0&
If strGladiator <> "" Then
AppActivate strGladiator, True
'Jag skickar key enter du kan skicka vilken key du vill
SendKeys "{ENTER}", True
End If
strGladiator = ""
End Sub

DS

Verkligen jätte schysst att du hjälper mig....
men det funkar inte.... :-(
vet inte om jag gör nåt fel eller så....

För att det inte ska bli något missförstånd så är det här hela fönstrets namn:

Gladiatorkampen på www.tv4.se - IE_Windows_Title

Fattar inte vad som är fel, du kanske ser det direkt så vad e det som inte fungerar?? :-(

Tack // R-mus