Är det enkelt, och i såfall hur gör jag för att skapa ett nytt mail (outlook) när jag trycker på en kommandoknapp?

Tacksam för hjälp

Nedan följer ett exempel klippt ur "Microsoft Automation 97 Help File"
/Curta


Sub SendMessage(DisplayMsg As Boolean, Optional AttachmentPath)
Dim objOutlook As Outlook.Application
Dim objOutlookMsg As Outlook.MailItem
Dim objOutlookRecip As Outlook.Recipient
Dim objOutlookAttach As Outlook.Attachment

' Create the Outlook session.
Set objOutlook = CreateObject("Outlook.Application")

' Create the message.

Set objOutlookMsg = objOutlook.CreateItem(olMailItem)

With objOutlookMsg
' Add the To recipient(s) to the message.
Set objOutlookRecip = .Recipients.Add("Nancy Davolio")
objOutlookRecip.Type = olTo

' Add the CC recipient(s) to the message.
Set objOutlookRecip = .Recipients.Add("Michael Suyama")
objOutlookRecip.Type = olCC

' Add the BCC recipient(s) to the message.

Set objOutlookRecip = .Recipients.Add("Andrew Fuller")
objOutlookRecip.Type = olBCC

' Set the Subject, Body, and Importance of the message.
.Subject = "This is an Automation test with Microsoft Outlook"
.Body = "This is the body of the message." & vbCrLf & vbCrLf
.Importance = olImportanceHigh 'High importance

' Add attachments to the message.
If Not IsMissing(AttachmentPath) Then

Set objOutlookAttach = .Attachments.Add(AttachmentPath)
End If

' Resolve each Recipient's name.
For Each objOutlookRecip In .Recipients
objOutlookRecip.Resolve
Next

' Should we display the message before sending?
If DisplayMsg Then
.Display
Else
.Send
End If

End With
Set objOutlook = Nothing
End Sub

Kan inget...vet inget....fattar inget

Nä ärligt..jag fattar inte vart jag ska skriva in det. kan du utveckla lite.
jag vill alltså bara att när jag trycker på kommandoknappen så ska ett mail öppnas

Hej igen...

Okey, En kommandoknapp som:

Startar Outlook ? eller

Öppnar ett befintligt mejl ? eller

Skapar ett nytt (tom) mejl, typ som att klicka "Arkiv", "Nytt" ?

Är det någon av dessa tre varianter eller exakt hur hade du tänkt dig, skall försöka bevaka ditt svar och återkomma mer detaljerat om hur du skall gör.

/Curta

ett nytt tomt mail ska det vara.

Klistra in följande i kodfönstret för formuläret:

Private Sub Command1_Click()
SkapaTomtMail
End Sub

Private Sub SkapaTomtMail()
Dim objOutlook As Outlook.Application
Dim objOutlookMsg As Outlook.MailItem

Set objOutlook = CreateObject("Outlook.Application")

Set objOutlookMsg = objOutlook.CreateItem(olMailItem)
objOutlookMsg.Display

Set objOutlook = Nothing
Set objOutlookMsg = Nothing
End Sub

Kryssa i "Microsoft Outlook98-objektmodell" Refernces under Projekt menyn

/Curta

Bockar och bugar! Tack så mycket, det fungerade perfekt!