Jag experimenterar med pixlar i en bild i syfte att analysera färger. Jag vill loopa igenom alla pixlar inom ett område i bilden med övre vänstra hörnet (x1,y1) och nedre högra hörnet (x2,y2). Om RGB är till exempel (92,190,87) skall pixeln färjas röd.
Naturligtvis blir loopen
For i = x1 to x2
For j = y1 to y2

mycket långsam när det handlar om 10 000 tal på x2 och y2

Finns det något snabbare sätt?

Om du vill loopa igenom ALLA pixlar så har du väl inte så mycket val?
Det enda tipset är väl att du bör använda integer.

Du skulle kunna göra en optimering genom att kolla var n:te pixel.

Det kan vara så att du kan tjäna tid på en do-loop istället för for-loop inuti den första for-loopen. (Du tjänar in en tilldelning per rad).

Sedan alla naturliga grejer; inte uppdatera bild osv.

/Niklas Jansson

hmmm, att använda en do-loop för att tjäna en tilldelning varje rad tycker jag låter dumt då man förlorar massor av klockcykler på själva villkorschecken...

Vad han skulle hunna göra är att byta plats på X och Y -loopen så han kollar radvis (bilden ligger lagrad så i minnet vilket ger en efffektivare minnehantering och högre sannolikhet för att bilden finns cachad) .

For i = x1 to x2
For j = y1 to y2

skulle alltså gå långsammare än

For i = y1 to y2
For j = x1 to x2


när det göller bildpixlar. Det skulle jag aldrig ha kommit på.

Hej
>Det enda tipset är väl att du bör använda integer.

Det är en missuppffatning,i 32 bitssystem skall du
använda Long.Om du använder Integer blir det ett
momment till dvs att dela upp den Long som processorn
skyfflar runt i två halvor och plocka ut Integer delen.

Long är den snabbaste datatypen i 32 bits system.

Du kan kolla mitt uppskick Programarkivet:138 , där scannar jag pixel.

mvh
Sven

>>Det enda tipset är väl att du bör använda integer.
>Det är en missuppffatning

Tack!
Det har jag faktiskt aldrig tänkt på.

(Det jag egentligen menade var i och för sig (använd inte flyttalstyper - och definitivt inte variant)

/Niklas Jansson

Hej
Kan tillägga att begreppet Long är på väg att försvinna.
tex i .net och Delphi ,förmodligen även i C++ så
Skalll man använda Integer. Där betyder Integer det
vi i Vb6 kallar för Long dvs 32 bit.

mvh
Sven

Kan ju tillägga att C++ är lite annorlunda i detta avseende.

Varken C- eller C++-standarden har inte sagt ett ord om hur stora integers skall vara.

I (åtminstone i äldre versioner av) Borland C++ så är en int på 16 bitar. I Microsoft Visual C++ är det 32.

I och med C# och den nya version som utvecklas parallellt (minns inte vad den heter), så kan typerna förhoppningsvis standardiseras.

/Niklas Jansson

Jepp finns ett mycket effektiv metod att snabba upp med API:
<code>
'Form: Form1
Private Sub Command1_Click()
ReplaceBits Picture1.Picture, 0, 0, ScaleX(Picture1.Picture.Width, vbHimetric, vbPixels), ScaleX(Picture1.Picture.Height, vbHimetric, vbPixels)
Picture1.Refresh
End Sub

'Modul: Module1
Option Explicit

Private Const BI_RGB = 0&
Private Const DIB_RGB_COLORS = 0 ' color table in RGBs

Private Type BITMAPINFOHEADER '40 bytes
biSize As Long
biWidth As Long
biHeight As Long
biPlanes As Integer
biBitCount As Integer
biCompression As Long
biSizeImage As Long
biXPelsPerMeter As Long
biYPelsPerMeter As Long
biClrUsed As Long
biClrImportant As Long
End Type
Private Type RGBQUAD
rgbBlue As Byte
rgbGreen As Byte
rgbRed As Byte
rgbReserved As Byte
End Type
Private Type BITMAPINFO
bmiHeader As BITMAPINFOHEADER
bmiColors As RGBQUAD
End Type
Private Declare Function CreateCompatibleDC Lib "gdi32" (ByVal hDC As Long) As Long
Private Declare Function CreateDIBSection Lib "gdi32" (ByVal hDC As Long, pBitmapInfo As BITMAPINFO, ByVal un As Long, ByVal lplpVoid As Long, ByVal handle As Long, ByVal dw As Long) As Long
Private Declare Function GetDIBits Lib "gdi32" (ByVal aHDC As Long, ByVal hBitmap As Long, ByVal nStartScan As Long, ByVal nNumScans As Long, lpBits As Any, lpBI As BITMAPINFO, ByVal wUsage As Long) As Long
Private Declare Function SetDIBitsToDevice Lib "gdi32" (ByVal hDC As Long, ByVal x As Long, ByVal y As Long, ByVal dx As Long, ByVal dy As Long, ByVal SrcX As Long, ByVal SrcY As Long, ByVal Scan As Long, ByVal NumScans As Long, Bits As Any, BitsInfo As BITMAPINFO, ByVal wUsage As Long) As Long
Private Declare Function SelectObject Lib "gdi32" (ByVal hDC As Long, ByVal hObject As Long) As Long
Private Declare Function DeleteDC Lib "gdi32" (ByVal hDC As Long) As Long
Private Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As Long
Private Declare Function BitBlt Lib "gdi32" (ByVal hDestDC As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, ByVal xSrc As Long, ByVal ySrc As Long, ByVal dwRop As Long) As Long

Public Function ReplaceBits(Picture As StdPicture, Left As Long, Top As Long, Width As Long, Height As Long)
Dim bi24BitInfo As BITMAPINFO
Dim bBytes() As Byte
Dim Cnt As Long

Dim hBitmapDC As Long
Dim hDIBitmapDC As Long
Dim hDIBSection As Long

ReDim bBytes(1 To Width * Height * 3) As Byte

With bi24BitInfo.bmiHeader
.biBitCount = 24
.biCompression = BI_RGB
.biPlanes = 1
.biSize = Len(bi24BitInfo.bmiHeader)
.biWidth = Width
.biHeight = Height
End With

hBitmapDC = CreateCompatibleDC(0)
SelectObject hBitmapDC, Picture.handle

hDIBitmapDC = CreateCompatibleDC(0)
hDIBSection = CreateDIBSection(hDIBitmapDC, bi24BitInfo, DIB_RGB_COLORS, ByVal 0&, ByVal 0&, ByVal 0&)

SelectObject hDIBitmapDC, hDIBSection

BitBlt hDIBitmapDC, 0, 0, Width, Height, hBitmapDC, Left, Top, vbSrcCopy

GetDIBits hDIBitmapDC, hDIBSection, 0, Height, bBytes(1), bi24BitInfo, DIB_RGB_COLORS

For Cnt = LBound(bBytes) To UBound(bBytes)
If bBytes(Cnt) < 50 Then
bBytes(Cnt) = 0
Else
bBytes(Cnt) = bBytes(Cnt) - 50
End If
Next

SetDIBitsToDevice hDIBitmapDC, 0, 0, Width, Height, 0, 0, 0, Height, bBytes(1), bi24BitInfo, DIB_RGB_COLORS

BitBlt hBitmapDC, Left, Top, Width, Height, hDIBitmapDC, 0, 0, vbSrcCopy

DeleteDC hBitmapDC
DeleteDC hDIBitmapDC
DeleteObject hDIBSection
End Function
</code>

Det går onekligen snabbt detta, men jag kan inte komma på hur man i detta kan ställa in så att om en pixel har rgb=50,75,68 så skall rgb ändras till 255.0.0 i bilden.

>(Det jag egentligen menade var i och för sig (använd inte flyttalstyper - och definitivt inte variant)



Hmm. Visserligen kan man använda dessa som enumerator i looparna.
Men det är ju lite dumt om man skall loopa för att kolla pixlar. Jag menar
det är lite svårt att titta på var 1,37:e pixel, så det ger sig självt att
man använder en heltalsdatatyp.

tycker peterh