Hej, jag har ett exceldokument med 4 kolumner á 2600 rader ca.
Jag vill lista ena kolumnen i en listbox.

vill sedan kunna klicka i denna och lista det som står på denna rad i de övriga kolumnerna.

Jag har kollat som fasen på forumet men hittar inget jag förstår, testade datakontrollen men den listar inte alla, bara en i taget.

Kan någon ge en liten vink om hur jag ska göra?

Kort exempel:
<code>
Option Explicit

Private mRecordset As ADODB.Recordset

Private Sub Combo1_Click()
If Combo1.ListIndex = -1 Then
Text1.Text = vbNullString
Text2.Text = vbNullString
Text3.Text = vbNullString
Text4.Text = vbNullString
Else
mRecordset.AbsolutePosition = Combo1.ListIndex + 1
Text1.Text = mRecordset(0)
Text2.Text = mRecordset(1)
Text3.Text = mRecordset(2)
Text4.Text = mRecordset(3)
End If
End Sub

Private Sub Form_Load()
Dim con As ADODB.Connection
Set con = New ADODB.Connection

con.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
"Data Source=" & App.Path & "\Book1.xls;" & _
"Extended Properties=""Excel 8.0;HDR=Yes;"";"

Set mRecordset = New ADODB.Recordset
mRecordset.CursorLocation = adUseClient
mRecordset.Open "SELECT * FROM [Sheet1$]", con, adOpenStatic, adLockReadOnly
Set mRecordset.ActiveConnection = Nothing
con.Close

Do Until mRecordset.EOF
Combo1.AddItem mRecordset(0)
mRecordset.MoveNext
Loop


End Sub

Private Sub Form_Unload(Cancel As Integer)
mRecordset.Close
Set mRecordset = Nothing
End Sub
</code>