Har en typ variabel enligt följande

Private Type KundData
KundNr As String
NAMN As String
ORGNR As String
MOMSREGNR As String
VALUTAKOD As String
...
osv
End Type

dim Kunder as kunddata

Innehåller minst 40 variabler
Finns det något enkelt sätt att tömma Kunder utan att
anropa dem en och sätta alla till ""

Jämför arrayer som töms med erase

<code></code>
Det är bara att tildela variabeln en tom variabel. T.ex:
<code>
Private Sub Test()
Dim Kund AS KundData
Dim EmptyKund AS KundData
Kund.KundNr = "007"
Kund.NAMN = "James Bond"
Kund.ORGNR = "N/A"
Kund.MOMSREGNR = "N/A"
Kund.VALUTAKOD = "SEK"

Kund = EmptyKund

Debug.Print "KundNr: " & Kund.KundNr
Debug.Print "NAMN: " & Kund.NAMN
Debug.Print "ORGNR: " & Kund.ORGNR
Debug.Print "MOMSREGNR: " & Kund.MOMSREGNR
Debug.Print "VALUTAKOD: " & Kund.VALUTAKOD

End Sub
</code>

För att slippa deklarera en variabel kan du skriva en funktion som retunerar en tom variabel:
<code>
Private Function EmptyKundData() As KundData

End Function

Private Sub Form_Load()
Dim Kund As KundData
Kund.KundNr = "007"
Kund.NAMN = "James Bond"
Kund.ORGNR = "N/A"
Kund.MOMSREGNR = "N/A"
Kund.VALUTAKOD = "SEK"

Kund = EmptyKundData

Debug.Print "KundNr: " & Kund.KundNr
Debug.Print "NAMN: " & Kund.NAMN
Debug.Print "ORGNR: " & Kund.ORGNR
Debug.Print "MOMSREGNR: " & Kund.MOMSREGNR
Debug.Print "VALUTAKOD: " & Kund.VALUTAKOD
End Sub
</code>