Kan man på nåt sätt kan se hur hårt accessmotorn belastas?
Att se hur många samtidiga kopplingar som är aktiva som mest?

Jag tror inte man kan se "belastning" på något sätt eller peak-värde för antalet anslutningar. Men man kan iaf se aktuellt antal anslutningar:

http://www.pellesoft.se/communicate/tips/tips.aspx?tid=1209

/Johan

Vid vilken händelse ska man lägga denna kod?

När du vill kolla hur många och vilka som är anslutna till databasen.

/Johan

Får detta fel vid test:

ADODB.Connection fel '800a0cb3'
Objektet eller providern kan inte utföra den begärda åtgärden.

Har du en öppen ADODB.Connection som heter con? (ser att jag inte har beskrivit det i exemplet)

/Johan

Hur ser din anslutningssträng ut? Använder du OLEDB providern för JET eller ODBC?

Function FixString(Text As String) As String
Dim pos As Long
    pos = InStr(1, Text, vbNullChar, vbBinaryCompare)
    If pos > 0 Then
        FixString = Left$(Text, pos - 1)
    Else
        FixString = Text
    End If
End Function

Dim strUsers As String
Dim intUsers As Integer

Dim rs As ADODB.Recordset
Dim fldLoginName As ADODB.Field
Dim fldComputerName As ADODB.Field

    Set rs = Connection.OpenSchema(adSchemaProviderSpecific, , "{947bb102-5d43-11d1-bdbf-00c04fb92675}")
    Set fldLoginName = rs("LOGIN_NAME")
    Set fldComputerName = rs("COMPUTER_NAME")
    
    Do Until rs.EOF
        strUsers = strUsers & FixString(fldLoginName.Value) & "@" & FixString(fldComputerName.Value) & vbCrLf
        intUsers = intUsers + 1
        rs.MoveNext
    Loop
    rs.Close
    

Men vart i kodfönstret lägger man detta? är det vi öppning av formuläret eller en knapptryckning ..eller..?
Ursäkta okunskapen

Öppnade med detta:

<%
dim con
set con= server.createobject("ADODB.Connection")
con.Open "DSN=databasensodbcnamn"
%>

Jag antar att du utvecklar i access?
Om så är fallet kan följande funktionen hjälpa dig.
* Skapa en ny modul.
* Klistra in koden i modulen.
* Lägg till en listbox i ditt formulär
* Ändra RowSourceType till: UserList

Private Data() As Variant

Public Function UserList(fld As Control, _
                         ByVal id As Long, _
                         ByVal row As Long, _
                         ByVal col As Long, _
                         ByVal code As Long) As Variant
                         
Dim rs As ADODB.Recordset
Dim con As ADODB.Connection
    Select Case code
        Case acLBInitialize     'Initialize
            Set con = CurrentProject.Connection
            Set rs = con.OpenSchema(adSchemaProviderSpecific, _
                                    , _
                                    "{947bb102-5d43-11d1-bdbf-00c04fb92675}")
            If rs.EOF Then
                UserList = False
            Else
                Data = rs.GetRows( _
                                  , _
                                  , _
                                  Array("LOGIN_NAME", "COMPUTER_NAME"))
                UserList = True
            End If
            rs.Close
        Case acLBOpen
            UserList = Timer
        Case acLBGetRowCount
            UserList = UBound(Data, 2) + 1
        Case acLBGetColumnCount
            UserList = 2
        Case acLBGetColumnWidth
            UserList = -1
        Case acLBGetValue
            UserList = Data(col, row)
        Case acLBEnd
            Erase Data
    End Select
End Function

Konstigt men hemma fungerar det men inte på jobbet...