hur gör man för att skicka en referens till ett image-objekt till en ocx
typ:
sub placePicture(oPicture As Image)

Du bör inte skicka referenser av interna vbobjekt som Image, Textbox, LAbel, etc. Du kan ju istället skicka bilden om det är det d är ute efter.

Här är ett litet exempel på en kontroll som har en bildegenskap:

Option Explicit

Private mPicture As StdPicture

Public Property Get Picture() As StdPicture
Set Picture = mPicture
End Property

Public Property Set Picture(vData As StdPicture)
Set mPicture = vData
End Property

Private Sub UserControl_InitProperties()
Set mPicture = LoadPicture("")
End Sub

Private Sub UserControl_Paint()
Dim X As Single
Dim Y As Single
Dim ImageWidth As Single
Dim ScaleRight As Single
If mPicture.Handle Then
ImageWidth = ScaleX(mPicture.Width)
ScaleRight = ScaleLeft + ScaleWidth
For Y = ScaleTop To ScaleTop + ScaleHeight Step ScaleY(mPicture.Height)
For X = ScaleLeft To ScaleRight Step ImageWidth
PaintPicture mPicture, X, Y
Next
Next
End If
End Sub

Private Sub UserControl_ReadProperties(PropBag As PropertyBag)
Set mPicture = PropBag.ReadProperty("Picture", LoadPicture(""))
End Sub

Private Sub UserControl_WriteProperties(PropBag As PropertyBag)
PropBag.WriteProperty "Picture", mPicture, LoadPicture("")
End Sub