Hur gör man det i Access 2000?
Vill inte att den ska automatisk spara det man skriver fören man trycker på sparar knappen.

Gäller det en post eller flera?

Är i ett formulär.
För att minimera risken att man tar fel och skriver fel så vill jag bara att den sparar om man trycker på sparar knappen.

Lättast är att visa en dialog när den försöker spara:

Private Sub Form_BeforeUpdate(Cancel As Integer)
On Error GoTo Form_BeforeUpdate_Err
    Select Case MsgBox("Posten har förändrats." + vbCrLf + "Vill du spara dina förändringar?", vbQuestion Or vbYesNoCancel)
    Case vbYes
        
    Case vbNo
        Cancel = True
        Me.Undo
    Case vbCancel
        Cancel = True
    End Select

Form_BeforeUpdate_Exit:
    Exit Sub

Form_BeforeUpdate_Err:
    MsgBox Err.Description, vbCritical
    Resume Form_BeforeUpdate_Exit

End Sub

Private Sub Form_Current()
On Error GoTo Form_Current_Err
    txtUserFirstName.Value = Me("UserFirstName")
    txtUserLastName.Value = Me("UserLastName")
    
Form_Current_Exit:
    Exit Sub

Form_Current_Err:
    MsgBox Err.Description, vbCritical
    Resume Form_Current_Exit
End Sub

Private Sub SaveButton_Click()
    Me("UserFirstName") = txtUserFirstName.Value
    Me("UserLastName") = txtUserLastName.Value
    DoCmd.RunCommand acCmdSaveRecord
End Sub

Tackar