Halloj.

Jag skulle behöva plocka ut lite tecken enligt följande mall:

[imgtext]HÄR kommer texten. Text text text[/imgtext]

Vad jag behöver är alltså alla tecken mellan [imgtext] och [/imgtext].

Någon sa att Regular expressions var ett smidigt sätt att göra detta.

Men efter att ha kollat lite på hur regexp funkar så kan jag säga att
det är total grekiska för min hjärna, kan bara inte få något grepp om detta.

Någon som kan låna en hjälpande hand?

Detta regexp kommer sedan användas på en .asp sida.

//Johannes

Hej

Använd detta reguljära uttrycket:
<code>
\[imgtext\](.*?)\[/imgtext\]
</code>

<b>Exempel på implementering</b>

<%
Dim text
Dim reg, matches

' Text to search through.
text = "12[imgtext]Hello[/imgtext]" & vbcrlf & "abc[imgtext]Hello again![/imgtext]de"

' Set up regular expression object.
Set reg = New RegExp
reg.Pattern = "\[imgtext\](.*?)\[/imgtext\]"
reg.IgnoreCase = False
reg.Global = True

' Get matches.
Set matches = reg.Execute(text)

' Any matches?
If matches.Count > 0 Then
 ' Print
 For Each match in matches
  Response.Write match.submatches(0) & "<br>"
 Next

' No matches.
Else
 Response.Write "No matches."
End If

' Dispose object
Set reg = nothing
%>

Man tackar.

Jag har lyckats med en själv nu tack vare ditt svar och Expresso.

Vill ha ut tvåan i följande rad

tillägg(x2)


och fick det att funka genom

<code>
Tillägg[(]x([0-9]?)
</code>