Hej,
Jag arbetar på en arbetsbok i Excel med en hel del VBA-kod och det enda som nu återstår är att användarna ska kunna välja skrivare när de ska skriva ut från arbetsboken. Eftersom det är en hel del kod runt utskrifterna funkar inte den "vanliga" Excel-utskriften utan utskriften måste göras i VBA. Jag har inte lyckats att på något sätt ändra från standardskrivaren utan att först gå in på bladet, välja skriv ut, välja skrivare och sedan avbryta utskriften.

Det skulle vara helt OK bara jag kunde få fram alla tillgängliga (installerade) skrivare så att jag kunde lägga det i en listbox där användarna kan markera önskad skrivare men jag lyckas inte med det heller. Jag har försökt att följa ett råd som innehöll följande kod för att få fram tillgängliga skrivare:

Public Sub ListPrinters()

Dim objPrinter As Access.Printer
Dim strPrinterList As String

For Each objPrinter In Printers
strPrinterList = strPrinterList & _
objPrinter.DeviceName & vbCrLf
Next objPrinter

MsgBox Prompt:="The device names of all of " & _
"the printers accessible by this computer " & _
"are:" & vbCrLf & strPrinterList

End Sub

men när jag kör denna kod får jag upp meddelandet "En funktion eller variabel förväntas" och den markerar "Printers" i For-satsen.

Kan någon vara snäll och hjälpa mig att få rätt på detta?

Gunilla

Prova

Application.Dialogs(xlDialogPrinterSetup).Show

Stort tack för hjälpen! Det löste mitt problem.

Tar upp den här tråden igen, eftersom jag själv dykt på ett
projekt där jag behöver en lista eller en Array med namnen på
de skrivare som finns installerade på klienten.
Det svar jag gav till Gunilla räcker inte då.

Koden som hon presenterade i första inlägget
fungerar om man lägger in en referens till
Access objekbibliotek.
Det kanske inte är installerad på klienten
Men finns det ingen lösning utan att man behöver
lägga till denna referens?

Här finns en metod som jag tror går att trixa lite med: http://pubs.logicalexpressions.com/Pub0009/LPMArticle.asp?ID=183
Där finns även en länk till http://www.mvps.org/vb/, där du kan titta på "Samples". Under där finns "PrnInfo.zip", det kanske kan vara något?

Tack för snabbt svar

Hittade denna länk på ditt första förslag

http://www.mvps.org/word/FAQs/MacrosVBA/AvailablePrinters.htm


<code>
Const PRINTER_ENUM_CONNECTIONS = &H4
Const PRINTER_ENUM_LOCAL = &H2

Private Declare Function EnumPrinters Lib "winspool.drv" Alias "EnumPrintersA" _
(ByVal flags As Long, ByVal name As String, ByVal Level As Long, _
pPrinterEnum As Long, ByVal cdBuf As Long, pcbNeeded As Long, _
pcReturned As Long) As Long

Private Declare Function PtrToStr Lib "kernel32" Alias "lstrcpyA" _
(ByVal RetVal As String, ByVal Ptr As Long) As Long

Private Declare Function StrLen Lib "kernel32" Alias "lstrlenA" _
(ByVal Ptr As Long) As Long


Public Function ListPrinters() As Variant

Dim bSuccess As Boolean
Dim iBufferRequired As Long
Dim iBufferSize As Long
Dim iBuffer() As Long
Dim iEntries As Long
Dim iIndex As Long
Dim strPrinterName As String
Dim iDummy As Long
Dim iDriverBuffer() As Long
Dim StrPrinters() As String

iBufferSize = 3072

ReDim iBuffer((iBufferSize \ 4) - 1) As Long

'EnumPrinters will return a value False if the buffer is not big enough
bSuccess = EnumPrinters(PRINTER_ENUM_CONNECTIONS Or _
PRINTER_ENUM_LOCAL, vbNullString, _
1, iBuffer(0), iBufferSize, iBufferRequired, iEntries)

If Not bSuccess Then
If iBufferRequired > iBufferSize Then
iBufferSize = iBufferRequired
Debug.Print "iBuffer too small. Trying again with "; _
iBufferSize & " bytes."
ReDim iBuffer(iBufferSize \ 4) As Long
End If
'Try again with new buffer
bSuccess = EnumPrinters(PRINTER_ENUM_CONNECTIONS Or _
PRINTER_ENUM_LOCAL, vbNullString, _
1, iBuffer(0), iBufferSize, iBufferRequired, iEntries)
End If

If Not bSuccess Then
'Enumprinters returned False
MsgBox "Error enumerating printers."
Exit Function
Else
'Enumprinters returned True, use found printers to fill the array
ReDim StrPrinters(iEntries - 1)
For iIndex = 0 To iEntries - 1
'Get the printername
strPrinterName = Space$(StrLen(iBuffer(iIndex * 4 + 2)))
iDummy = PtrToStr(strPrinterName, iBuffer(iIndex * 4 + 2))
StrPrinters(iIndex) = strPrinterName
Next iIndex
End If

ListPrinters = StrPrinters

End Function


'You could call the function as follows:

Sub Test()

Dim StrPrinters As Variant, x As Long

StrPrinters = ListPrinters

'Fist check whether the array is filled with anything, by calling another function, IsBounded.
If IsBounded(StrPrinters) Then
For x = LBound(StrPrinters) To UBound(StrPrinters)
Debug.Print StrPrinters(x)
Next x
Else
Debug.Print "No printers found"
End If

End Sub

Public Function IsBounded(vArray As Variant) As Boolean
'If the variant passed to this function is an array, the function will return True;
'otherwise it will return False
On Error Resume Next
IsBounded = IsNumeric(UBound(vArray))
End Function

</code>

Snabbtestade den och den verkar fungera utmärkt

Tackar